Posted on 2010-10-14 11:42
幻海藍夢 閱讀(187)
評論(0) 編輯 收藏 所屬分類:
版本管理
包括以下功能：
1、只允許用戶修改自己的日志。可以設(shè)置超級用戶，超級用戶可以修改其他人的日志，其他人只能修改自己的日志。
2、只允許對日志進行操作，不允許對其它屬性操作。
3、只允許對日志進行修改，不允許增加、刪除日志。
腳本如下：
@ECHO OFF
REM 限制日志文件的個數(shù)采用修改項目屬性的tsvn:logminsize，不在腳本中限制
REM 參數(shù)
set repos=%1
set rev=%2
set user=%3
set propname=%4
set action=%5
REM 設(shè)置超級用戶，超級用戶可以修改其他人的日志，其他人只能修改自己的日志
set superUser=ygq
REM 只允許日志svn:log的修改
if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME
REM 只允許修改日志，增加、刪除等操作不允許
if /I not '%action%'=='M' goto ERROR_ACTION
REM 只允許用戶修改自己的日志
for /f "usebackq" %%k in (`svnlook author %repos% -r %rev%`) do @set var=%%k
set rightUser=0
if "%3" == "%superUser%" set rightUser=1
if "%3" == "%var%" set rightUser=1
if %rightUser% == 0 goto ERROR_USER
goto :SUCCESS_EXIT
:ERROR_USER
echo 只允許用戶修改自己的日志 >&2
goto ERROR_EXIT
:ERROR_PROPNAME
echo 只有日志信息能被修改 >&2
goto ERROR_EXIT
:ERROR_ACTION
echo 只允許修改日志，不允許增加、刪除等操作 >&2
goto ERROR_EXIT
:ERROR_EXIT
exit 1
:SUCCESS_EXIT
exit 0
原文：http://hi.baidu.com/gacmotor/blog/item/9b923b0f28400dcd7acbe108.html