在上篇中我們提到了AsBroadcaster類包裝的廣播器作為事件源的諸多限制，現在就看看EventDispatcher(派遣)類是如何拓展事件源的功能吧。
EventDispatcher類有2個靜態方法:
----------------------------------------------
static function initialize(object:Object):Void
//object:對象
//initialize:初始化方法，為對象object附加上作為事件源(在這里可以理解為派遣中心吧)的各項功能。
static function _removeEventListener(queue:Object, event:String, handler):Void
//一個內部方法,注銷監聽事件源相關事件的監聽者
-------------------------------------------------
EventDispatcher類有4個公共方法:
function dispatchEvent(eventObj:Object):Void
/*事件派遣方法，向外界廣播一個消息，并附有關于消息的相關描述(請與broadcastMessage(msg:String)方法比較)
eventObj:事件對象，它至少應含有2個屬性,假設司令部為一個事件派遣中心，一般定義如下:
var eventObj=new Object();
eventObj.target=司令部;//定義廣播消息的對象
eventObj.type="on進攻";//定義消息的具體類型

其中target屬性也可以不定義，dispatchEvent方法會將它設為默認的廣播消息的對象。
*/
function dispatchQueue(queueObj:Object, eventObj:Object):Void
/*這個方法的中文意思，我根據它的功能將它稱為"事件傳達"。
queueObj:一個事件派遣中心對象
eventObj:事件對象,注意:與 dispatchEvent不同，它的target并無默認值，需要你手工設定.
為什么將這個方法稱為事件傳達呢?因為它可以讓當前的事件派遣中心指示另一個事件派遣中心(方法的第一個參數)向外界廣播消息。其實在dispatchEvent方法的內部就調用了dispatchQueue，只是將參數queueObj設為當前的事件派遣中心罷了。
*/
function addEventListener(event:String, handler):Void
/*注冊某個事件的監聽者
event:監聽的事件名稱
handler:監聽事件的對象
這個方法與AsBroadcaster類的addListener方法相比，多出了參數event，
明確了所監聽的具體事件。
*/
function removeEventListener(event:String, handler)
/*注銷某個事件的監聽者
event:事件名稱
handler:要注銷的監聽事件的對象
這個方法與AsBroadcaster類的removeListener方法相比，多出了參數event，明確了從哪個事件中注銷監聽對象。
*/
----------------------------------------------------------
下面就讓我們在戰場上實戰一下EventDispatcher吧。假設有兩個指揮中心，一個是司令部，一個是戰地指揮部。有三個兵種，分別是炮兵、步兵和敢死隊。司令部可以指揮炮兵的進攻、駐守和步兵的駐守，戰地指揮部可以指揮步兵的進攻、沖鋒和敢死隊的沖鋒，并且司令部可以向戰地指揮部傳達指示。下面是實現上述復雜關系的代碼:
-----EventDispatcher測試.fla 開始-----
import mx.events.EventDispatcher;
//導入 mx.events.EventDispatcher類
var 司令部 = new Object();
司令部.名稱 = "司令部";
EventDispatcher.initialize(司令部);
//為司令部對象附加上派遣中心的相關功能。
var 戰地指揮部 = new Object();
戰地指揮部.名稱="戰地指揮部";
EventDispatcher.initialize(戰地指揮部);
//為戰地指揮部對象附加上派遣中心的相關功能。

var 步兵 = new Object();
步兵.on進攻 = function(eventObj) {
　　　　　//步兵的'on進攻'事件處理方法，記住需要有參數
var 來自=eventObj.target.名稱;
　　　　　//eventObj.target引用廣播'on進攻'事件的對象，用它可以訪問事件源并反饋消息。
var 陣地=eventObj.陣地;
　　　　　 //獲取事件的關于' 陣地'屬性值
trace("步兵接到"+來自+"來電，輕裝上陣，火速向敵方"+陣地+"前進!");
};
步兵.on駐守 = function(eventObj) {
var 來自=eventObj.target.名稱;
trace("步兵接到"+來自+"來電，就地待命，多設崗哨,嚴防來犯之敵!");
};
步兵.on沖鋒=function(eventObj){
var 來自=eventObj.target.名稱;
var 陣地=eventObj.陣地;
trace("步兵接到"+來自+"來電，向敵方"+陣地+"發起沖鋒!");

}
司令部.addEventListener("on駐守", 步兵);
//向司令部的'on駐守'事件注冊監聽對象'步兵'
戰地指揮部.addEventListener("on進攻", 步兵);
//向司令部的'on進攻'事件注冊監聽對象'步兵'
戰地指揮部.addEventListener("on沖鋒",步兵);
//向戰地指揮部的'on沖鋒'事件注冊監聽對象'步兵'
var 炮兵 = new Object();
炮兵.on進攻 = function(eventObj) {
var 來自=eventObj.target.名稱;
var 陣地=eventObj.陣地;
trace("炮兵接到"+來自+"來電，向敵方"+陣地+"陣地猛烈轟擊!");
};
炮兵.on駐守 = function(eventObj) {
var 來自=eventObj.target.名稱;
trace("炮兵接到"+來自+"來電，就地待命，保證彈藥準備充足!");
};
司令部.addEventListener("on駐守", 炮兵);
司令部.addEventListener("on進攻", 炮兵);
var 敢死隊=new Object();
敢死隊.on沖鋒=function(eventObj){
var 來自=eventObj.target.名稱;
var 陣地=eventObj.陣地;
trace("敢死隊接到"+來自+"來電，向敵方"+陣地+"發起沖鋒!拼死也要拿下！");
}
戰地指揮部.addEventListener("on沖鋒",敢死隊);

//---------------------------------------------------------------------
trace("司令部指示:");
var eventObj1 = new Object();
//定義事件對象eventObj1
eventObj1.target = 司令部;
//定義事件對象eventObj1的target屬性值為司令部
eventObj1.type = "on進攻";
//定義事件對象的事件類型為'on進攻'
eventObj1.陣地="505陣地"
//一個自定義的屬性'陣地',你可以附加更多其他的屬性
司令部.dispatchEvent(eventObj1);
//司令部將定義好的事件對象廣播出去，只有向它注冊了'on進攻'屬性的監聽對象才能收到。步兵并不會發動進攻。
trace("戰地指揮部指示:");
var eventObj2=new Object();
//eventObj2.target=戰地指揮部;
//因為dispatchEvent方法會自動將事件對象的target屬性設為默認的廣播消息的對象，所以這句也可以注釋掉。
eventObj2.type = "on進攻";
eventObj2.陣地="105陣地"
戰地指揮部.dispatchEvent(eventObj2);
trace("傳達司令部指示:");
var eventObj3=new Object();
eventObj3.target=戰地指揮部;
//這里必須設定事件對象的target屬性。因為dispatchQueue不會為target屬性設定默認值
eventObj3.type="on沖鋒";
eventObj3.陣地="123陣地";
司令部.dispatchQueue(戰地指揮部,eventObj3);
//戰爭時期也許司令部并不知道前線部隊的布置情況，所以它可以將指令傳達給戰地指揮部，由戰地指揮部將事件對象廣播給向自己的相關事件注冊的監聽對象
-----EventDispatcher測試.fla 結束-----
具體的測試結果我就不貼出來了。最后說說EventDispatcher類的幾個有趣的地方:
1、監聽事件的對象可以是Object、MovieClip，還可以是Function.例如：
假設在戰場上每當發起沖鋒時，都要吶喊助威，可以這樣寫：
function 鼓勵士氣(){
trace("沖啊!殺啊!");
}
戰地指揮部.addEventListener("on沖鋒",鼓勵士氣);
2、當監聽事件的對象是自身時,一般的寫法是這樣的:
戰地指揮部.on沖鋒=function(){
trace("同志們，我們一定會取得最后的勝利！");
}
戰地指揮部.addEventListener("on沖鋒",戰地指揮部);
但是還有一種更簡潔的寫法:
戰地指揮部.on沖鋒Handler=function(){
trace("同志們，我們一定會取得最后的勝利！");
}
這種寫法不再需要用"addEventListener"來注冊了。它有兩點需要注意,一是它總在其他監聽對象的事件處理之前執行，再就是它無法用'removeEventListener'方法注銷監聽。
3、監聽對象的事件處理程序也可以這樣寫:
步兵.handlerEvent=function(eventObj){
var 來自=eventObj.target.名稱;
var 陣地=eventObj.陣地;
var e=eventObj.type;
switch(e){
case "on進攻":
trace("步兵接到"+來自+"來電，輕裝上陣，火速向敵方"+陣地+"前進!");
break;
case "on駐守":
trace("步兵接到"+來自+"來電，就地待命，多設崗哨,嚴防來犯之敵!");
break;
case "on沖鋒":
trace("步兵接到"+來自+"來電，向敵方"+陣地+"發起沖鋒!");
break;
default:
break;
}
司令部.addEventListener("on駐守", 步兵);
戰地指揮部.addEventListener("on進攻", 步兵);
戰地指揮部.addEventListener("on沖鋒",步兵);

好了，關于EventDispatcher類到此就介紹完了，希望大家能夠掌握Flash的事件機制并靈活地運用它們。