|
第 1 樓
部分代碼：
*用WORD創建新文檔，再根據DBF的資料創建自幾所需要的表格文檔
Thisform.chnagedbf &&轉表查詢生成新表、公用變量k,arrcolor[j,k],arrWash[1],arrCrock[1]
WAIT windows("起動WORD制做文檔，請稍等....") NOWAIT AT MROW(Thisform.Name,3),MCOL(Thisform.Name,3)
OleWord=CREATEOBJECT('word.application') &&創建word目標
OleWord.Visible=.F. &&word隱藏，為.F.可在后臺操作
OleWord.Documents.add() &&增加新的word文檔
*-- 頁面設置
WITH OleWord.ActiveDocument.PageSetup
*1．設置頂邊距為2厘米
.TopMargin=2/0.035
*2．設置底邊距為4厘米
.BottomMargin=4/0.035
*3．設置左邊距為2厘米
.LeftMargin=2/0.035
*4．設置右邊距為2厘米
.RightMargin=2/0.035
*頁面0為縱向，1為橫向
.Orientation=1
ENDWITH
**********************************************************************************
WITH OleWord.Selection
.TypeParagraph &&回車符
.Text="致" &&加完是選定狀態
.Font.size=20 &&字體大小
.Moveright(3,1) &&加完是選定狀態，移動一次才不覆蓋,3是右移參數，左移1字節。
.TypeParagraph
.insertafter(SPACE(4)+"興啟")
.Font.size=20
.Moveright(3,1)
.TypeParagraph
.Moveright(3,1)
.insertafter(SPACE(6)+"多謝貴公司的支持，貴公司在我廠所配COT樣辦牢度如下：")
.Font.size=14
.Moveright(3,1)
.TypeParagraph
ENDWITH
******創建表格*******************************
OleWord.Selection.TypeParagraph
OleWord.Selection.TypeParagraph
OleWord.Selection.Moveup(5,1) &&第一個5是上移參數，第二個數字是上移1行,留一空行在格表下面
otemp=OleWord.Selection.Range
OleWord.ActiveDocument.Tables.Add(otemp,k+3,6,5,0) &&插入k+3行6列表格
OleWord.Selection.SelectRow
&&光標在第一格，要移動用Moveright() 等
WITH OleWord.Selection
.Tables(1).Rows.Height=0.77/0.035 &&選定表格所有行高0.77CM
.Tables(1).Columns.PreferredWidth=2.5/0.035 &&選定表格所有列寬 1.9cm
.Tables(1).Columns(1).PreferredWidth=4.73/0.035 &&選定表格第一列寬 4.73cm
*添加數據,表格合并后就不能用此方法加資料
.Tables(1).rows(3).cells(3).range.insertafter("顏色變化")
.Tables(1).rows(3).cells(4).range.insertafter("顏色沾色")
.Tables(1).rows(3).cells(5).range.insertafter("干 擦")
.Tables(1).rows(3).cells(6).range.insertafter("濕 擦")
FOR i=1 TO k
FOR j=1 TO 6
.Tables(1).rows(i+3).cells(j).range.insertafter(arrcolor[i,j])
ENDFOR
ENDFOR
**選定合并
.MoveLeft(3,1) &&左移去掉選定.第一個3是左移參數，第二個數字是左移1字節
.MoveDown(5,2,1) &&下移兩格，5是下移參數，2是移兩格，1是按SHIFT,選擇3格
.Cells.Merge &&合并選定的三格
.MoveRight(3,1) &&右移去掉選定.第一個3是右移參數，第二個數字是右移1格
.MoveDown(5,2,1)
.Cells.Merge &&合并選定的三格
.MoveRight(3,1) &&右移一格去掉選定
.Moveright(3,2,1) &&3是右移參數，右移1格,最后1是按SHIFT鍵，變成選定二格。
.Cells.Merge &&合并選定的兩格
.MoveDown(5,1)
.Moveright(3,2,1) &&3是右移參數，左移1格,最后1是按SHIFT鍵，變成選定二格。
.Cells.Merge &&合并選定的兩格
.Moveright(3,1) &&右移一格去掉選定
.Moveright(3,2,1) &&3是右移參數，左移1格,最后1是按SHIFT鍵，變成選定二格。
.Cells.Merge &&合并選定的兩格
.Moveup(5,1) &&上移一格，5是下移參數，2是移兩格，1是按SHIFT,選擇3格
.Moveright(3,2,1)
.Cells.Merge
***加入資料,因要合并不方便操作，所以合并后加放標題資料
.insertafter("摩 擦")
.MoveDown(5,1)
.insertafter(arrCrock[1])
.MoveLeft(3,2)
.insertafter(arrWash[1])
.Moveup(5,1)
.insertafter("耐 洗")
.MoveLeft(3,2)
.insertafter("顏 色")
.MoveLeft(3,2)
.insertafter("色 號")
.MoveDown(5,k,1) &&5是下移參數，下移k+2格,最后1是按SHIFT鍵，變成選定多格。
.MoveRight(3,5,1) &&3是右移參數，右移5格,最后1是按SHIFT鍵，變成選定多格。
.ParagraphFormat.Alignment=1 && 1居中 2左對齊，3右對齊，4分散對齊
.MoveDown(5,1)
.TypeParagraph
.insertafter(SPACE(4)+"祝")
.MoveRight(3,1)
.TypeParagraph
.insertafter("生意興隆！")
.MoveRight(3,1)
.TypeParagraph
.insertafter(SPACE(25)+"先科有限公司")
.Font.size=20
.Moveright(3,1)
.TypeParagraph
.insertafter(SPACE(30)+DTOC(DATE()))
.Moveright(3,1)
ENDWITH
MESSAGEBOX("制作文檔完畢!",64,"提示")
OleWord.Visible=.T. | |