使用ADO控件可以方便的在VB6中訪問ODBC數據庫，但是通過直接放置ADODS控件來獲得ADO的數據連接比較麻煩，我們可以在VB工程中創建一個公共數據模塊，將ADO控件的初始化、建立連接、關閉連接等操作都寫到函數中，這樣就可以在工程的其他模塊中共享調用這個ADO連接。
一次完整的ADO調用操作分為如下幾個步驟：
1.打開ADO到數據庫的連接，初始化ADO RECORDSET集。
2.通過寫入SQL語句執行查詢并返回查詢結果RECORDSET集；或者可以通過寫入SQL語句執行相應數據庫操作。
3.釋放RECORDSET集，關閉數據庫連接。
需要注意的是，每個動態創建的ADO同時只能被一個過程調用，如果需要進行多表并行操作，可能需要在公共數據模塊中建立多個動態ADO。
下面是相關的代碼：

'-----------------------------------------------------------------
'如下代碼保存在名為my.bas的工程模塊中
Public CONN As Adodb.Connection        '定義ADO CONNECTION對象
Public RS As Adodb.Recordset           '定義ADO RECORDSET對象
'****************************
'打開數據庫連接
'****************************
Function ConnOpen()                   
  Dim ASTR As String
  Set CONN = New Adodb.Connection
  ASTR = GetDatabasePath  'MDB文件數據庫路徑
  CONN.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & ASTR & ";Persist Security Info=False"
  '本例的ODBC連接為JET4.0的直接到MDB文件的連接，如果使用ODBC數據源可以使用如下CONNECTION串：
  'Provider=MSDASQL.1;Password="";Persist Security Info=True;Data Source=數據源名稱;Initial Catalog=數據表庫名稱
  CONN.Open
  Set RS = New Adodb.Recordset
  With RS Do
    ActiveConnection = CONN
    CursorType = adOpenDynamic
    LockType = adLockOptimistic
  End With
End Function
'****************************
'關閉數據庫
'****************************
Function ConnClose()                       
   Set RS = Nothing
   CONN.Close
   Set CONN = Nothing
End Function

'**********************************************************
'        獲得數據庫路徑
'  本例數據庫保存在程序目錄下的DBS子目錄中，名為db1.mdb
'**********************************************************
Public Function GetDatabasePath() As String
    Dim sPath As String
    If Right$(App.Path, 1) = "\" Then
        sPath = App.Path + "dbs\"
    Else
        sPath = App.Path + "\dbs\"
    End If
   
    GetDatabasePath = sPath + "db1.mdb"
End Function
'End of my.bas
'-----------------------------------------------------------------

如下示例代碼為my.bas的使用方法：
'-----------------------------------------------------------------
'使用RS對象執行SELECT語句
'TableName和FieldName分別為表名和字段名
'查詢結果保存在數組s中
Private Sub RunSelectCommand()
    Dim s(99) as String
    Dim i as Integer
    i=0
    Call my.ConnOpen
        my.RS.Open "SELECT * FROM TableName"
        While Not RS.EOF
            i=i+1
            If Not isNull(my.RS!FieldName) Then s(i)=Cstr(my.RS!FieldName)
            RS.MoveNext
        Wend
    Call my.ConnClose
End Sub
'使用CONN對象執行UPDATE/DELETE/INSERT語句
'SQL語句放在變量sSQL中
Private Sub RunSqlCommand()
    Dim sSQL as String
    Call my.ConnOpen
        my.CONN.Execute sSQL
    Call my.ConnClose
End sub
'對于DATAGRID和DATAREPORT這些需要DATASOURCE的控件可以做如下操作
'使用SELECT語句打開RS的數據集
Set OBJ.Datasource=my.RS
'---------------------------------------------------------------------
這個方法對于開發簡單小型的MIS系統很實用，也可以在報表和數據表中使用，缺點是在多表操作和函數嵌套調用時，一個動態ADO對象不能同時執行兩個工作，后一個寫入的SQL語句會覆蓋先寫入的SQL語句，當在回到前一個過程時，會因為字段找不到而出錯。因此如果可能需要進行多表操作，可以嘗試多定義幾個CONN 和RS對象。

>> 將文本賦值給MsFlexGrid的單元格
MsFlexGrid.TextMatrix(3,1)=”Hello”

>> 在MsFlexGrid控件單元格中插入背景圖形
Set MsFlexGrid.CellPicture=LoadPicture(“C:\temp\1.bmp”)

>>選中某個單元
MsFlexGrid.Row=1
MsFlexGrid.Col=1

>>用粗體格式化當前選中單元
MsFlexGrid.CellFontBold=True

>> 添加新的一行
使用AddItem方法,用Tab字符分開不同單元格的內容
dim row as string
row=”AAA”&vbtab&”bbb”
MsFlexFrid1.addItem row

>>怎樣來實現MSFlexGrid控件單數行背景為白色，雙數的行背景為藍色?
    Dim i As Integer
    With MSFlexGrid1
         .AllowBigSelection = True    ’ 設置網格樣式
         .FillStyle = flexFillRepeat
         For i = 0 To .Rows - 1
             .Row = i: .Col = .FixedCols
             .ColSel = .Cols() - .FixedCols - 1
             If i Mod 2 = 0 Then
                .CellBackColor = &HC0C0C0    ’ 淺灰
             Else
                .CellBackColor = vbBlue ’ 蘭色
             End If
         Next i
     End With

>> MSFlexGrid控件如何移到最后一行
MSFlexGrid1.TopRow = MSFlexGrid1.Rows – 1

>>如何判斷msflexgrid有無滾動條
Declare Function GetScrollRange Lib "user32" (ByVal hWnd As Long, ByVal nBar As Long, lpMinPos As Long, lpMaxPos As Long) As Long

Public Const SB_HORZ = &H0
Public Const SB_VERT = &H1

Public Function VsScroll(MshGrid As MSHFlexGrid) As Boolean           ’判斷水平滾動條的可見性
Dim i As Long
VsScroll = False
i = GetScrollRange(MshGrid.hWnd, SB_HORZ, lpMinPos, lpMaxPos)
If lpMaxPos <> lpMinPos Then VsScroll = True
End Function

Public Function HeScroll(MshGrid As MSHFlexGrid) As Boolean           ’判斷垂直滾動條的可見性
Dim i As Long
HeScroll = False
i = GetScrollRange(MshGrid.hWnd, SB_VERT, lpMinPos, lpMaxPos)
If lpMaxPos <> lpMinPos Then HeScroll = True
End Function

>>程序運行時，想動態增加MSFlexgrid的列數
在第2列后插入一列：
Private Sub Form_Load()
Me.MSHFlexGrid1.Cols = 5
MSHFlexGrid1.Rows = 2
For i = 0 To Me.MSHFlexGrid1.Cols - 1
Me.MSHFlexGrid1.TextMatrix(0, i) = i
Me.MSHFlexGrid1.TextMatrix(1, i) = i
Next
End Sub

Private Sub Command1_Click()
Me.MSHFlexGrid1.Cols = Me.MSHFlexGrid1.Cols + 1
Me.MSHFlexGrid1.ColPosition(5) = 3
End Sub

>> MSFlexGrid中的對齊功能的使用
設置MSFlexGrid1.ColAlignment(index)=n

>>得到MSFlexGrid控件中當前選中的一行
msflexgrid1.rowsel就是當前選中行

>> 如何通過代碼調節列寬度
msflexgrid1.colwidth(i)=4000
增加 MsFlexGrid 的編輯功能

概述
MsFlexGrid 控件沒有提供文本編輯的功能，下面的例子演示了如何利用一個TextBox 實現編輯當前網格的功能。

在按下一個鍵后， 就把TextBox 移動到當前的位置， 并激活。 在鍵入回車或移動到其他網格時， 就把TextBox 中的內容放到網格中。

實現步驟
1 打開 VB5， 開啟一個新的工程。

2 在菜單“工程” 中選擇 “部件”， 在列表中選中 “Microsoft FlexGrid Control ..”

3 放一個 MsFlexGrid 控件和一個TextBox 控件(Text1)到 Form1。 修改MsFlexGrid 控件的名稱為 Grid1， 設置Grid1 的行，列 為 4， 固定行，列為 0。 設置 Text1 的 Visiable 為 False， BorderStyle 為 None(0)。

4 在Form1 的代碼中增加聲明：

Const ASC_ENTER = 13 '回車
Dim gRow As Integer
Dim gCol As Integer

5 增加代碼到 Grid_KeyPress 過程：

Private Sub Grid1_KeyPress(KeyAscii As Integer)
' Move the text box to the current grid cell:
Text1.Top = Grid1.CellTop + Grid1.Top
Text1.Left = Grid1.CellLeft + Grid1.Left
' Save the position of the grids Row and Col for later:
gRow = Grid1.Row
gCol = Grid1.Col
' Make text box same size as current grid cell:
Text1.Width = Grid1.CellWidth - 2 * Screen.TwipsPerPixelX
Text1.Height = Grid1.CellHeight - 2 * Screen.TwipsPerPixelY
' Transfer the grid cell text:
Text1.Text = Grid1.Text
' Show the text box:
Text1.Visible = True
Text1.ZOrder 0 ' 把 Text1 放到最前面！
Text1.SetFocus
' Redirect this KeyPress event to the text box:
If KeyAscii <> ASC_ENTER Then
SendKeys Chr$(KeyAscii)
End If
End Sub

6 增加代碼到 Text1_KeyPress 過程：

Private Sub Text1_KeyPress(KeyAscii As Integer)
If KeyAscii = ASC_ENTER Then
Grid1.SetFocus ' Set focus back to grid, see Text_LostFocus.
KeyAscii = 0 ' Ignore this KeyPress.
End If
End Sub

7 增加代碼到 Text1_LostFocus 過程：

Private Sub Text1_LostFocus()
Dim tmpRow As Integer
Dim tmpCol As Integer
' Save current settings of Grid Row and col. This is needed only if
' the focus is set somewhere else in the Grid.
tmpRow = Grid1.Row
tmpCol = Grid1.Col
' Set Row and Col back to what they were before Text1_LostFocus:
Grid1.Row = gRow
Grid1.Col = gCol
Grid1.Text = Text1.Text ' Transfer text back to grid.
Text1.SelStart = 0 ' Return caret to beginning.
Text1.Visible = False ' Disable text box.
' Return row and Col contents:
Grid1.Row = tmpRow
Grid1.Col = tmpCol
End Sub

DataGrid 控件是一種類似于電子數據表的綁定控件，可以顯示一系列行和列來表示 Recordset 對象的記錄和字段。可以使用 DataGrid 來創建一個允許最終用戶閱讀和寫入到絕大多數數據庫的應用程序。DataGrid 控件可以在設計時快速進行配置，只需少量代碼或無需代碼。當在設計時設置了DataGrid 控件的 DataSource 屬性后，就會用數據源的記錄集來自動填充該控件，以及自動設置該控件的列標頭。然后您就可以編輯該網格的列；刪除、重新安排、添加列標頭、或者調整任意一列的寬度。
　　　　在運行時，可以在程序中切換 DataSource 來察看不同的表，或者可以修改當前數據庫的查詢，以返回一個不同的記錄集合。
　　　　注意 DataGrid 控件與 Visual Basic 5.0中的 DBGrid 是代碼兼容的，除了一個例外：DataGrid 控件不支持 DBGrid 的“解除綁定模式”概念。DBGrid 控件包括在 Visual Basic 的 Tools 目錄中。
　　　　可能的用法
　　　　查看和編輯在遠程或本地數據庫中的數據。
　　　　與另一個數據綁定的控件（諸如 DataList 控件）聯合使用，使用 DataGrid控件來顯示一個表的記錄，這個表通過一個公共字段鏈接到由第二個數據綁定控件所顯示的表。
　　　　使用 DataGrid 控件的設計時特性
　　　　可以不編寫任何代碼，只通過使用 DataGrid 控件的設計時特性來創建一個數據庫應用程序。下面的說明概要地說明了在實現 DataGrid 控件的典型應用時的一般步驟。完整的循序漸進的指示，請參閱主題“DataGrid 方案1: 使用 DataGrid 控件創建一個簡單數據庫應用程序”。
要在設計時實現一個 DataGrid 控件
　　　　1. 為要訪問的數據庫創建一個 Microsoft 數據鏈接 (.MDL) 文件。請參閱“創建 Northwind OLE DB 數據鏈接”主題，以獲得一個示例。
　　　　2. 在窗體上放置一個 ADO Data 控件，并將其 ConnectionString 屬性設置為在第 1 步中所創建的OLE DB 數據源。
　　　　3. 在這個 Ado Data 控件的 RecordSource 屬性中輸入一條將返回一個記
錄集的 SQL 語句。例如，Select * From MyTableName Where CustID = 12
　　　　4. 在窗體上放置一個 DataGrid 控件，并將其 DataSource 屬性設置為這個 ADO Data 控件。
　　　　5. 右鍵單擊該 DataGrid 控件，然后單擊“檢索字段”。
　　　　6. 右鍵單擊該 DataGrid 控件，然后單擊“編輯”。
　　　　7. 重新設置該網格的大小、刪除或添加網格的列。
　　　　8. 右鍵單擊該 DataGrid 控件，然后單擊“屬性”。
　　　　9. 使用“屬性頁”對話框來設置該控件的適當的屬性，將該網格配置為所需的外觀和行為。
　　　　在運行時更改顯示的數據
　　　　在創建了一個使用設計時特性的網格后，也可以在運行時動態地更改該網格的數據源。下面介紹實現這一功能的通常方法。
　　　　更改 DataSource 的RecordSource
　　　　更改所顯示的數據的最通常方法是改變該 DataSource 的查詢。例如，如果DataGrid 控件使用一個ADO Data控件作為其 DataSource，則重寫RecordSource和刷新該ADO Data 控件都將改變所顯示的數據。
　　　　' ADO Data 控件連接的是 Northwind 數據庫的' Products 表。新查詢查找所有
　　　　' SupplierID = 12 的記錄。
　　　　Dim strQuery As String
　　　　strQuery = "SELECT * FROM Suppliers WHERE SupplierID = 12"
　　　　Adodc1.RecordSource = strQuery
　　　　Adodc1.Refresh
　　　　更改 DataSource
　　　　在運行時，可以將 DataSource 屬性重新設置為一個不同的數據源。例如，您可能具有若干個 ADO Data 控件，每個控件連接不同的數據庫，或設置為不同的 RecordSource 屬性。可以簡單地將 DataSource 從一個 ADO Data控件重新設置為另一個 ADO Data 控件：
　　　　' 將 DataSource 重新設置為一個連接到 Pubs 數據庫的、
　　　　' 使用 Authors 表的 ADO Data 控件。
　　　　Set DataGrid1.DataSource = adoPubsAuthors
　　　　重新綁定 DataSource
　　　　當將 DataGrid 控件用于一個遠程數據庫，諸如 SQLServer 時，可以改變表的結構。例如，可以給這個表添加一個字段。在這種情形下，可以調用Rebind 方法根據新的結構來重新創建該網格。注意，如果已經在設計時改變了這個列的布局，DataGrid 控件將會試圖重新創建當前的布局，包括任何空的列。不過，通過首先調用 ClearFields 方法，可以強制該網格重新設置所有的列。
　　　　從 DataGrid 返回值
　　　　在 DataGrid 被連接到一個數據庫后，可能想要監視用戶單擊了哪一個單元。可以使用 RowColChange 事件——而不是 Click 事件。如下所示：
　　　　Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
　　　　　　　' 顯示用戶所單擊的單元的文字、行和列的信息。
　　　　　　　Debug.Print DataGrid1.Text; DataGrid1.Row; DataGrid1.Col
　　　　End Sub
　　　　使用 CellText 和 CellValue 方法
　　　　當一個列使用 NumberFormat 屬性設置格式后，CellText 和 CellValue 屬性是很有用的。NumberFormat 屬性不必更改實際的數據格式就可以更改任何包含數字的列的格式。例如，給定一個網格，其中包含一個名為 ProductID的、包含整數的列。下面的代碼將使 DataGrid 以"P-0000" 的格式來顯示數據。換句話說，盡管在 ProductID 字段中所包含的實際數值為 "3"，但該網格所顯示的值將是 "P-0003"。
　　　　　　Private Sub Form_Load()
　　　　　　　　DataGrid1.Columns("ProductID").NumberFormat = "P-0000"
　　　　　　End Sub
　　　　要返回數據庫中所包含的實際值，應使用 CellValue 方法，如下所示：
　　　　　　Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
　　　　　　　　Debug.Print _
　　　　　　　　DataGrid1.Columns("ProductID").CellValue(DataGrid1.Bookmark)
　　　　　　End Sub
　　　　注意 上面所用的 CellValue 和下面所用的 CellText 值，都需要將Bookmark 屬性作為一個參數，功能才正確。
　　　　相反地，如果要返回該字段的格式化的值，應使用 CellText 方法：
　　　　　　Private Sub DataGrid1_RowColChange(LastRow As Variant, ByVal LastCol As Integer)
　　　　　　　　Debug.Print _
　　　　　　　　DataGrid1.Columns("ProductID").CellText(DataGrid1.Bookmark)
　　　　　　End Sub
　　　　注意 上面的 CellText 方法等價于使用 DataGrid 控件的 Text 屬性。
　　　　下一步
　　　　要閱讀關于使用該控件創建簡單的應用程序的一個循序漸進的過程，請參閱“使用 DataGrid 控件創建簡單的數據庫應用程序”，或“創建一個連接DataList 控件的 DataGrid”。
　　　　要了解關于 Split 對象以及如何對其編程的詳細信息，請參閱“操作DataGrid 視圖”。
　　　　創建 Northwind 的OLE DB 數據鏈接
　　　　訪問數據的一個重要步驟是為想要訪問的每個數據庫都創建一個 OLE DB數據源。下面的步驟為 Visual Basic 所提供的Nwind.mdb (Northwind) 數據庫創建這樣一個對象。這個數據源被用于 Visual Basic 文檔所提供的一些示例過程。在一個計算機上只需要創建一次OLE DB數據源。
　　　　要創建 Northwind 的OLE DB 數據源
　　　　1. 打開 Windows Explorer或 Windows NT Explorer。
　　　　2. 打開您想要創建 OLE DB 數據源的目錄。在該示例中，打開 ProgramFiles、Microsoft Visual Studio和VB98。
　　　　3. 右鍵單擊 Explorer 的右邊窗格，然后單擊上下文菜單上的“新建”。從文件類型列表中單擊“Microsoft 數據鏈接”。
　　　　4. 重命名新文件 Northwind.MDL。
　　　　5. 右鍵單擊文件并單擊上下文菜單上的“屬性”，以顯示“Northwind.MDLProperties”對話框。
　　　　6. 單擊“連接”選項卡。
　　　　7. 單擊“提供方”框并選擇“Microsoft Jet 3.51 OLE DB Provider”。
　　　　8. 在Data Source 框中輸入nwind.mdb文件的路徑。
　　　　9. 單擊“測試連接”，檢測連接。
　　　　10. 如果連接通過，單擊“確定”。
　　　　注意 也可以通過在“控制面板”中單擊“數據鏈接”圖標創建一個 OLE DB數據源。在“管理數據鏈接文件”對話框中，單擊“新建”創建一個新的數據源。
　　　　使用 DataGrid 和 ADO Data控件創建一個簡單的數據庫應用程序
　　　　只使用一個 DataGrid 和一個 ADO Data 控件，可以創建一個允許最終用戶閱讀和寫入記錄集的數據庫應用程序。
　　　　要使用 ADO 數據控件來創建一個簡單的數據庫應用程序
　　　　1. 為 Northwind 數據庫創建一個OLE DB 數據源。如果還沒有創建數據源，請按照“創建 Northwind 的OLE DB Data Link”中的步驟操作。
　　　　2. 在Visual Basic 中創建一個新的標準的 EXE 工程。如果 DataGrid 控件不在“工具箱”中，則用右鍵單擊“工具箱”，然后使用“部件”對話框來添加控件。同時也載入 ADO 控件。
　　　　3. 在空窗體上各放置控件的一個實例。
　　　　4. 將 ADO 控件的ConnectionString 屬性設置為 Northwind 的數據源。單擊并選定該 ADO Data 控件，并按 F4 鍵出現“屬性”窗口。單擊“ConnectionString”，然后單擊 OLE DB File。單擊 Northwind 的數據源。
　　　　5. 設置 ADO 控件的 RecordSource 屬性。在“屬性”窗口中，單擊“記錄源”并輸入一條 SQL 語句來填充 DataGrid
控件。在本例中，輸入“Select * From Products”。
　　　　6. 將 DataGrid 控件的 DataSource 屬性設置為這個 ADO Data 控件。單擊并選定該 DataGrid 控件。在其“屬性”窗口中，單擊“數據源”將出現一個包含所有數據控件的下拉列表——在本例中只有 ADO Data 控件。單擊這個控件。
　　　　7. 按 F5 鍵運行這個工程。
　　　　創建一個連接 DataList 控件的 DataGridData
　　　　Grid 的通常用法是顯示數據庫的一個表所提供的“詳細內容”。例如，Northwind (Nwind.mdb) 數據庫包括兩個表，一個名為 "Suppliers"，另一個名為 "Products"。在本例中，我們使用 DataList 控件來顯示 "Suppliers" 表中的供應商的公司名稱。當用戶單擊任意一個公司名稱時，這個 DataList 控件將提供該公司的 SupplierID。使用這個標識符，就可以構造一個查詢，在 "Products" 表中檢索具有相匹配的 SupplierID 的所有記錄。換句話說，當用戶單擊一個公司時（在 DataList 控件中），該公司生產的所有產品將出現在 DataGrid 控件中。
要使用一個指定供應商的產品填充一個 DataGrid 控件
　　　　1. 確認在機器上已為 Northwind 數據庫建立了一個OLE DB 數據源；如果還沒有創建這樣的一個數據源，請按照“創建 Northwind 的OLE DBData連接”的步驟操作。
　　　　2. 在Visual Basic 中創建一個新的標準的 EXE 工程。
　　　　如果 DataGrid、DataList 和 ADO Data 控件不在“工具箱”中，則右鍵單擊“工具箱”，然后單擊“部件”。在“部件”對話框中雙擊“MicrosoftDataGrid Control”、“Microsoft DataList Controls”以及“Microsoft ADOControl”。
　　　　3. 在一個空窗體中各放置一個 DataGrid 和 DataList 控件的實例。將 DataList 控件放置在該窗體的左上角，然后將 DataGrid 控件放在它的下面的某處。
　　　　4. 在窗體放置兩個 ADO Data 控件實例。選擇第一個 ADO Data 控件，并按 F4 鍵來顯示其“屬性頁”。將該控件的 Name 屬性設置為 adoSuppliers。選擇第二個 ADO Data 控件并將其 Name 屬性設置為 adoProducts。將第一個控件直接放在 DataList 控件的下面，把第二個控件直接放在 DataGrid 控件的下面。
　　　　5. 將這兩個 ADO Data 控件的 ConnectionString 屬性設置為 Northwind的OLE DB 數據源。選擇名為 adoSuppliers 的控件，然后將其ConnectionString 屬性設置為Northwind 的OLE DB data source (Northwind.mdl)。選擇名為 adoProducts的控件，并重復該操作。
　　　　6. 設置這兩個 ADO Data 控件的 RecordSource 屬性。選擇 adoSuppliers 并在其“屬性頁”上單擊“RecordSoure”。輸入 Select* From Suppliers。這個查詢將指示該 ADO Data 控件返回 Suppliers 表中的所有記錄。選擇 adoProducts，單擊“RecordSoure”，并輸入 Select *From Products。這個查詢將返回在 Products 表中的所有記錄。
　　　　7. 將 DataList 控件的 RowSource 屬性設置為 adoSuppliers。
　　　　　RowSource 屬性決定由哪一個數據源為 ListField 屬性供應數據。
　　　　8. 將 DataList 控件的 ListField 屬性設置為 CompanyName。
　　　　　ListField 屬性被設置成名為 Suppliers 的表中的字段名稱。在運行時，DataList 控件顯示在這個屬性中所指定的字段的值。在本例中，該屬性將顯示在 Suppliers 表中找到的一個公司名稱。
　　　　9. 將 DataList 控件的 BoundColumn 屬性設置為 SupplierID。
　　　　　BoundColumn 屬性被設為 Suppliers 表中的第二個字段。在本例中，這個屬性就被設為 SupplierID 字段。當單擊 DataList 控件時，BoundText屬性返回與在 DataList 控件中所顯示的公司相關聯的 SupplierID 字段的值。這個值將用于對 Products 表的查詢，該查詢為 DataGrid 控件提供數據。
　　　　10. 將 DataGrid 控件的 DataSource 屬性設置為 adoProducts。
　　　　　DataSource 屬性為該控件指定數據源。在本例中，該屬性被設置為名為adoProducts 的 ADO Data 控件，這將返回 Products 表中的所有記錄。
　　　　11. 在窗體的代碼模塊中，添加下述內容：
　　　　　　Private Sub Datalist1_Click()
　　　　　　' 聲明一個用來包含新查詢的字符串變量。這個新的
　　　　　　' 查詢使用 DataList 控件的BoundText屬性
　　　　　　' 來提供一個 SupplierID 值。新查詢查找所有
　　　　　　' 具有相同的 SupplierID 的產品。這個查詢被
　　　　　　' 指定給名為 adoProducts 的 ADO Data 控件
　　　　　　' 的 RecordSource 屬性。在刷新控件后，DataGrid
　　　　　　' 將使用包含由同一個公司供應的所有產品的新
　　　　　　' 記錄集來更新。
　　　　　　Dim strQuery As String
　　　　　　strQuery = "Select * FROM Products WHERE SupplierID = " & _
　　　　　　Datalist1.BoundText
　　　　　　With adoProducts
　　　　　　　　.RecordSource = strQuery
　　　　　　　　.Refresh
　　　　　　End With
　　　　　　With DataGrid1
　　　　　　　　.ClearFields
　　　　　　　　.ReBind
　　　　　　End With
　　　　　　End Sub
　　　　12. 運行該工程。
　　　　單擊 DataList 控件中的任意公司名稱，將自動用該公司所供應的產品更新 DataGrid 控件。

使用列
　　　　通過更改 DataSource 屬性，可以動態地更改在 DataGrid 控件中顯示的數據。例如，可以顯示同一個數據庫的不同表。如果這樣做，則 DataGrid 控件將只根據默認的屬性顯示數據。
　　　　添加、刪除或隱藏列
　　　　通過使用 Columns 集合和 Column 對象的屬性和方法，可以在程序中添加、刪除或隱藏列。
　　　　添加和刪除一列
　　　　要在運行時添加一列，可以使用 Add 方法。如果首先聲明一個變量，并將新對象賦給該變量，就可以用簡明的代碼設置各種屬性。
　　　　Private Sub AddColumn()
　　　　　　' 在最右邊的位置添加一列。然后設置其 Visible、Width、
　　　　　　' Caption以及 Alignment 屬性。DataField 屬性則指定
　　　　　　' 該列將綁定到哪一個字段。
　　　　　　Dim c As Column
　　　　　　Set c = DataGrid1.Columns.Add(DataGrid1.Columns.Count)
　　　　　　With c
　　　　　　　.Visible = True
　　　　　　　.Width = 1000
　　　　　　　.Caption = "我的新列"
　　　　　　　.DataField = Adodc1.Recordset.Fields("ProductName").Name
　　　　　　　.Alignment = dbgRight
　　　　　　End With
　　　　End Sub
　　　　可以使用方法來刪除任意一列。請確保使用 ColIndex 參數來指定要刪除的列。下面的代碼將刪除被單擊的列。
　　　　Private Sub DataGrid1_HeadClick(ByVal ColIndex As Integer)
　　　　　　　DataGrid1.Columns.Remove ColIndex
　　　　End Sub
　　　　隱藏一列
　　　　通過將 Visible 屬性設置為 False，可以隱藏任意一列。當想要限制用戶可以查看或編輯的列時這一功能特別有用。下面的示例在 Columns 集合中循環，隱藏除少數列之外的所有列。
　　　　Private Sub HideColumns()
　　　　　　' 使用 DataField 屬性來判別正在測試的是哪一列。
　　　　　　' 只顯示三列：ProductName、UnitPrice以及
　　　　　　' UnitsInStock。
　　　　　　Dim c As Column
　　　　　　For Each c In DataGrid1.Columns
　　　　　　　　　Select Case c.DataField
　　　　　　　　　Case "ProductName"
　　　　　　　　　　　c.Visible = True
　　　　　　　　　Case "UnitPrice"
　　　　　　　　　　　c.Visible = True
　　　　　　　　　Case "UnitsInStock"
　　　　　　　　　　　c.Visible = True
　　　　　　　　　　　c.Caption = "In Stock" 　　　' 更改這個列的標頭。
　　　　　　　　　Case Else　　　　　　　　　　　　 ' 隱藏其它所有的列。
　　　　　　　　　　　c.Visible = False
　　　　　　　　　End Select
　　　　　　Next c
　　　　End Sub
　　　　操作 DataGrid 視圖
　　　　一個“拆分”的網格使最終用戶對相同的數據可以擁有多個視圖。例如，假設有一個由十個字段組成的大表。在這種情況下，在控件中察看的記錄集將有十列寬，除非窗體非常寬，否則用戶將無法同時看見所有列的內容。，而且，假設用戶只對第一列和最后一列感興趣（例如，第一列是名字，最后一列是電話號碼）。為了能同時看到在兩端的列（不重新安排列的順序），可以對網格進行拆分。
　　　　創建一個 Split 對象
　　　　在設計時，可以創建一個拆分，具體步驟是：右鍵單擊網格，單擊“編輯”，再單擊右鍵，然后單擊“拆分”。通過右鍵單擊該控件，并單擊“屬性”來顯示“屬性頁”對話框，可以編輯這個拆分。可以使用“拆分”選項卡來自定義拆分。要刪除一個拆分，右鍵單擊該拆分，并單擊“刪除”。
　　　　在運行時，最終用戶也可以通過單擊位于這個網格控件的左下邊的右邊的選項卡，以手工方式來拆分該網格（除非不允許這個操作），如下圖所示：
 
默認情況下，DataGrid 控件包含一個 Split 對象。防止最終用戶添加拆分的代碼為：
　　　　DataGrid1.Splits(0).AllowSizing = False
　　　　在程序中添加和刪除拆分
　　　　DataGrid 控件包含一個 Split 對象的集合。要在程序中添加拆分，可以使用 Add 方法，如下所示：
　　　　DataGrid1.Splits.Add 1
　　　　注意 Add 方法需要新的拆分索引作為其參數。要添加一個拆分，應將這個索引參數設置為 Splits 集合的 Count 屬性值。
　　　　使用 Split 集合的 Add 方法，可以在程序中按照實際需要添加拆分。由于添加多于兩個以上的拆分將使網格很難使用，可以使用該集合的 Count 屬性來限制拆分的數目。
　　　　If DataGrid1.Splits.Count < 3 Then ' 添加一個拆分。
　　　　　　　DataGrid1.Splits.Add DataGrid1.Splits.Count
　　　　End If
　　　　使拆分同步
　　　　當拆分多于一個時，可能希望控制這些拆分如何滾動。例如，在一個具有三個拆分的網格中，可以決定只讓第一個和第三個拆分同步，而讓中間的拆分獨立地滾動。要同步任何兩個（或多個）拆分，只需將每個 Split 對象的 ScrollGroup 屬性設置為同一個值。
　　　　' 使第一個和第三個 Split 對象同步。
　　　　With DataGrid1
　　　　　　.Splits(0)
　　　　.ScrollGroup = 1
　　　　.Splits(1).ScrollGroup = 2
　　　　.Splits(2).ScrollGroup = 1
　　　　End With
　　　　通過設置 Scrollbars 屬性，使同步的拆分組只顯示一個滾卷條，從而進一步自定義拆分的外觀。
　　　　控制 Tab 鍵和箭頭鍵的行為
　　　　使用 WrapCellPointer、TabAcrossSplits以及 TabAction 屬性，可以決定當最終用戶按下 tab 鍵或箭頭鍵時網格的行為。
　　　　在這三個屬性中，TabAction 屬性級別最高，它決定 WrapCellPointer 和TabAcrossSplits 這兩個屬性是否能生效。TabAction 有三個設置值： ControlNavigation、Column Navigation 和 Grid Navigation。當該屬性設置為 ControlNavigation 時，按 Tab 鍵根據 TabIndex 將焦點切換到下一個控件。這一設置優先于 WrapCellPointer 和 TabAcrossSplits。
　　　　WrapCellPointer 屬性決定在任何單個的拆分中 tab 鍵和箭頭鍵的行為。如果該屬性設置為 True，且當前單元位于最后一列，這時最終用戶按 tab 鍵則使第一列的下一行變成當前的單元。不過，如果當前單元位于最后一行的最后一列時，這時就沒有地方可以“換行”。
　　　　TabAcrossSplits 屬性決定當網格中存在兩個或多個拆分時 tab 和箭頭鍵的行為。如果該屬性設置為 True，且當前單元位于任何一個拆分的最后一列，則按Tab或箭頭鍵將使當前單元“跳” 到下一個拆分的第一列。當前單元仍保持相同的行位置。
　　　　注意 如果 WrapCellPointer 和 TabAcrossSplits 屬性都設置為 True，則只有當前單元位于最后一個拆分的最后一列時才會換行。這時當前單元將換到第一個拆分的第一列中的下一行。
　　　　自定義列集合
　　　　每一個 Split 對象都有一個 Columns 屬性，允許用戶來操作一個 Column對象的集合。通過這樣做，可以更改每個 Split 對象的外觀。例如，可以用一個拆分包含顯示姓氏字段和名字字段的兩個列，而第二個拆分則顯示電話字段和地址字段。要實現這一目標，需要將其它的每一列的 Visible 屬性設置為 False，如下所示：
　　　　' 枚舉 Columns 集合，對每一個 Column 對象的 DataField 屬性
　　　　' 進行測試。如果測試失敗，則隱藏這一列。
　　　　Dim i As Integer
　　　　' 隱藏除 ProductName 列之外的所有列。
　　　　For i = 0 To DataGrid1.Splits(0).Columns.Count - 1
　　　　　　If DataGrid1.Splits(0).Columns(i).DataField <> "ProductName" Then
　　　　　　　　　DataGrid1.Splits(0).Columns(i).Visible = False
　　　　　　End If
　　　　Next i
　　　　' 隱藏除 UnitPrice 列之外的所有列。
　　　　For i = 0 To DataGrid1.Splits(0).Columns.Count - 1
　　　　　　If DataGrid1.Splits(1).Columns(i).DataField <> "UnitPrice" Then
　　　　　　　　　DataGrid1.Splits(1).Columns(i).Visible = False
　　　　　　End If
　　　　Next I
　　　使用 Bookmarks 和 SelBookmarks 跟蹤記錄
　　　　Bookmarks 和 SelBookmarks 提供了標記記錄的一種手段。當編寫應用程序中的特定功能（諸如允許最終用戶手工地選擇多個不相鄰的記錄，進行所選記錄的大批更新）時，這就很有必要。在這些情形中，需要標記哪些記錄已被選擇，因此可以使用 SelBookmarks 集合及其屬性。
　　　　有兩個函數，分別是 CellText 和 CellValue 方法，需要標記才能正確執行。
　　　　標記用戶的選擇
　　　　SelBookmarks 集合包含所有選定的記錄的書簽。當最終用戶手工選擇記錄時（即在單擊時按住 CTRL 鍵），每一個選定的記錄的書簽都會加入到該集合中。使用標準的循環，用戶可以知道已經選定了什么，也可以保存書簽（因為可能需要恢復某個值），以及執行操作：
　　　　Dim i as Integer ' 計數器
　　　　Dim intCount As Integer
　　　　intCount = DataGrid1.SelBookmarks.Count - 1
　　　　ReDim arrSelBK(intCount) ' 聲明用于保存書簽的數組。
　　　　For i = 0 To intCount
　　　　　　ArrSelBK(i) = DataGrid1.SelBookmarks(i)
　　　　　　' 在此處執行操作。如果該操作必須被
　　　　　　' 取消，則退出該循環，然后使用該數
　　　　　　' 組來取消這些更改。
　　　　Next i
　　　　通過在程序中添加到 SelBookmarks 集合來選擇記錄
　　　　通過將記錄添加到這個集合，也可以在程序中選定記錄。例如，可能有一個顯示指定的客戶所有訂貨的網格。如果要高亮顯示該客戶花費超過 $100的所有記錄，則對記錄進行過濾，并將結果書簽添加到 SelBookmarks 集合。
　　　　Dim rs As Recordset
　　　　Set rs = Adodc1.Recordset
　　　　While Not rs.EOF
　　　　　　If rs!SupplierID = 12 Then
　　　　　　　　DataGrid1.SelBookmarks.Add rs.Bookmark
　　　　　　End If
　　　　　　rs.MoveNext
　　　　Wend
　　　　顯示計算結果字段
　　　　假設在表中有一個名為 "Price" 的字段，并且想使用本地稅率來計算表中每一項的稅費。這就是一個計算結果字段，可以通過修改 DataSource 的查詢來計算這個值，并把這個值返回給 DataGrid 控件。
　　　　要在 DataGrid 控件中創建一個計算結果字段
　　　　1. 確認在機器上已為 Northwind 數據庫建立了一個OLE DB 數據源；如果還沒有創建這樣的一個數據源，請按照“創建 Northwind 的OLE DBData 連接”的步驟操作。
　　　　2. 在窗體上放置一個 ADO Data 控件和一個 DataGrid 控件。
　　　　3. 將 ADO Data 控件的ConnectionString 屬性設置為 Northwind 的數據源。
　　　　4. 設置 ADO Data 控件的 RecordSource 屬性。在“屬性”窗口中，單擊“記錄源”并輸入 Select ProductName, UnitPrice,(UnitPrice * .082) As Tax From Products。
　　　　5. 將 DataGrid 控件的 DataSource 屬性設置為這個 ADO Data 控件。
　　　　6. 運行該工程。
　　　　與類模塊一起使用 DataGrid 控件
　　　　如果想要訪問以自定義格式或以 ODBC 驅動程序不直接支持的格式存放的數據，可以創建一個類來封裝該數據。然后可以編寫該類的自定義函數來檢索這些數據。這樣該類就變成了一種數據源，可以被任何數據使用者（如DataGrid 控件）使用。
　　　　在這個類模塊的Initialize 事件中，首先通過聲明一個作為 New　ADODB.Recordset的變量，來創建一個 ADODB recordset 對象。在創建了這個 recordset 對象后，再添加字段，每個數據源中的每個字段都要加入。然后使用合適的數據填充這個記錄集。
　　　　注意 也可以使用 OLEDB 示例提供者來創建一個數據源。關于 OLEDB示例提供者的詳細信息，請參閱“創建帶有數據提供方的部件”。
　　　　類模塊有一個 GetDataMember 事件，只要當數據使用者（諸如 DataGrid 控件）需要數據時就產生該事件。在這個事件中，Data 參數被設置為在Initialize 事件中所創建的 recordset 對象。
　　　　如果要使用這個類模塊，應創建一個具有一個 DataGrid 控件的窗體。在該窗體的 Load 事件的代碼中，將該控件的 DataSource 屬性設置為這個類。
　　　　注意 數據類模塊在設計時是不可用的。例如，如果使用 DataGrid 控件，則當用戶在“屬性”窗口中單擊“數據源”時，所有可用的數據源都會出現在一個下拉列表中。但其中不會有這個數據類模塊，它只能在代碼中設置。
　　　　使用類模塊創建一個數據源
　　　　下面的示例使用一個類模塊來創建一個簡單數據源。然后通過 DataSource屬性將 DataGrid 控件綁定到該模塊。
要創建一個用于DataGrid 的類
　　　　1. 創建一個新的標準 Exe 工程。
　　　　2. 給窗體添加一個 DataGrid 控件。如果DataGrid控件不在“工具箱”中，則在“工程”菜單中單擊“部件”，
再單擊“Microsoft DataGrid Control”，然后單擊“確定”。
　　　　3. 在“工程”菜單中，單擊“引用”。在“引用”對話框中，單擊“MicrosoftActiveX Data Objects 2.0 Library”。
　　　　4. 在“工程”菜單中，單擊“添加類模塊”來給工程添加一個數據類模塊。
　　　　5. 在“工程資源管理器”窗口中，單擊并選定“類”圖標，并按 F4 鍵顯示“屬性”窗口。
　　　　6. 在“屬性”窗口中，將類的名稱更改為NamesData。
　　　　7. 在“屬性”窗口中，單擊“DataSourceBehavior”并將該屬性更改為vbDataSource。
　　　　8. 在該類模塊的 Declarations 部分，創建一個 ADODB Recordset變量，如下所示：
　　　　Option Explicit
　　　　Private WithEvents rsNames As ADODB.RecordSet
　　　　使用 WithEvents 關鍵詞來聲明該變量，使用戶可以對 RecordSet 對象的事件編程。
　　　　9. 在該類的 Initialize 事件中，添加下述代碼：
　　　　Private Sub Class_Initialize()
　　　　　　' 將新的數據成員的名稱添加到 DataMember 集合
　　　　　　' 這使其它對象可以看見這些可用的
　　　　　　DataMembersDataMembers.Add "Names"
　　　　　　Set rsNames = New ADODB.RecordSet　　　 ' 設置對象變量。
　　　　　　' 創建一個具有兩個字段的 recordset，并打開該 recordset。
　　　　　　' 第一個記錄具有一個整數的數據類型，第二個記錄是一個最大可
　　　　　　' 達 256 個字符的字符串。CursorType 被設置為 OpenStatic
　　　　　　' —— 一個可更新的對一組記錄的快照。LockType 被設置為
　　　　　　' LockOptimistic，以允許對該 recordset 進行更新。
　　　　　　With rsNames
　　　　　　　　.Fields.Append "ID", adInteger
　　　　　　　　.Fields.Append "Name", adBSTR, 255
　　　　　　　　.CursorType = adOpenStatic
　　　　　　　　.LockType = adLockOptimistic
　　　　　　　　.Open
　　　　　　End With
　　　　　　Dim i As Integer
　　　　　　For i = 1 to 10 　　' 添加十條記錄。
　　　　　　　　rsNames.AddNew
　　　　　　　　rsNames!ID = i
　　　　　　　　rsNames!Name = "Name " & i
　　　　　　　　rsNames.Update
　　　　　　Next i
　　　　　　rsNames.MoveFirst ' 移到該記錄集的開始。
　　　　End Sub
　　　　這部分代碼首先創建 recordset 對象，然后給該對象添加兩個字段。代碼接著給 recordset 添加十條記錄。
　　　　10. 在該類的 GetDataMember 事件中，添加下述代碼 ：
　　　　Private Sub Class_GetDataMember(ByVal DataMember As String, _
　　　　Data As Object)
　　　　　　　Set Data = rsNames
　　　　End Sub
　　　　只要發生該事件——即當該類對象被綁定到一個數據使用者，如 DataGrid控件時，代碼將返回該 recordset 對象。
　　　　11. 在 Form 對象的代碼模塊中，聲明一個數據類的對象變量：
　　　　Option Explicit
　　　　Private datNames As NamesData ' 類變量
　　　　12. 在 Form 對象的 Load 事件的代碼中，將 DataGrid 控件的 DataSource設置為該類對象。
　　　　　Private Sub Form_Load()
　　　　　　　' 創建一個新的 NamesData 對象
　　　　　　　Set datNames = New NamesData
　　　　　　　' 將這個 DataGrid 綁定到新的數據源 datNames
　　　　　　　Set DataGrid1.DataSource = datNames
　　　　　End Sub
　　　　13. 按 F5 鍵運行該工程。
　　　　RecordSet事件的編程
　　　　也可以對這個 Recordset 對象的事件進行編程。在該類模塊中，單擊“對象”框（在位于左上角），然后單擊“rsNames”。在“過程/事件”框（在右上角）中，下拉列表將顯示這個 Recordset 對象的所有事件。
　　　　給類添加一個屬性
　　　　類模塊也可以進行修改，來響應事件或函數調用。下面的代碼演示了如何先給類添加屬性。當從其它對象調用該對象時，這一屬性將返回該類的RecordCount。
　　　　Public Property Get RecordCount() As Long
　　　　　　　RecordCount = rsNames.RecordCount
　　　　End Sub
　　　　使用 DataMember 屬性
　　　　GetDataMember 事件也包括 DataMember 參數。使用這個參數，可以在類模塊中包括多個記錄集，并使用帶 DataMember 參數的 Select Case 語句來返回相應的記錄集：
　　　　Private Sub Class_GetDataMember(ByVal DataMember As String, Data As _
　　　　Object)
　　　　　　　Select Case DataMember
　　　　　　　Case "Names"
　　　　　　　　　Set Data = rsNames
　　　　　　　Case "Dates"
　　　　　　　　　Set Data = rsDates
　　　　　　　Case Else
　　　　　　　　　' 設置一個默認的數據成員
　　　　　　　　　Set Data = rsYears
　　　　　　　End Select
　　　　End Sub
　　　　如果要指定所需的 DataMember，請將數據使用者的 DataMember 屬性設置為適當的字符串，然后如平常一樣設置 DataSource。對于 DataGrid 控件，可以采用如下方法：
　　　　Private Sub Form_Load()
　　　　　　　' 創建一個新的 NamesData 對象
　　　　　　　Set datNames = New NamesData
　　　　　　　' 指定所需的 DataMember，然后設置 DataSource。
　　　　　　　DataGrid1.DataMember = "Names"
　　　　　　　Set DataGrid1.DataSource = datNames
　　　　End Sub

引言

　　作為微軟旗下一款優秀的RAD工具，VB在數據庫應用開發方面的能力十分強大。微軟設計了多種數據庫訪問方法，下面通過對VB訪問數據庫的多種技術進行深入剖析，并總結出實際開發中的幾點經驗。希望能夠對那VB的初學者有所幫助。（注意，文中所有的描述均在Windows 2000 professional和Visual Basic 6.0的環境下進行的）

一. DAO、RDO、ODBC和ADO

　　在VB的開發環境中，可以使用三種數據庫訪問方式，它們分別是：數據訪問對象(DAO)、遠程數據對象（RDO）和ADO對象模型。

　　DAO：

　　數據訪問對象是用來顯露了Microsoft Jet數據庫引擎（最早是給Microsoft Access 所使用，現在已經支持其它數據庫），并允許開發者通過ODBC直接連接到其他數據庫一樣，直接連接到 Access 表。DAO 最適用于單系統應用程序或在小范圍本地分布使用。其內部已經對Jet數據庫的訪問進行了加速優化，而且其使用起來也是很方便的。所以如果數據庫是Access數據庫且是本地使用的話，建議使用這種訪問方式。

　　VB已經把DAO模型封裝成了Data控件，分別設置相應的DatabaseName屬性和RecordSource屬性就可以將Data控件與數據庫中的記錄源連接起來了。以后就可以使用Data控件來對數據庫進行操作。

　　RDO

　　RDO（Remote Data Objects）遠程數據對象是一個到ODBC的、面向對象的數據訪問接口，它同易于使用的DAO style組合在一起，提供了一個接口，形式上展示出所有ODBC的底層功能和靈活性。盡管RDO在很好地訪問Jet或ISAM數據庫方面受到限制，而且它只能通過現存的ODBC驅動程序來訪問關系數據庫。但是，RDO已被證明是許多SQL Server、Oracle 以及其他大型關系數據庫開發者經常選用的最佳接口。RDO提供了用來訪問存儲過程和復雜結果集的更多和更復雜的對象、屬性，以及方法。

　　和DAO一樣，在VB中也把其封裝為RDO控件了，其使用方法與DAO控件的使用方法完全一樣。

　　ODBC

　　ODBC(Open Database Connectivity，開放數據庫互連)是微軟公司開放服務結構(WOSA,Windows Open Services Architecture)中有關數據庫的一個組成部分，它建立了一組規范，并提供了一組對數據庫訪問的標準API（應用程序編程接口）。這些API利用SQL來完成其大部分任務。ODBC本身也提供了對SQL語言的支持，用戶可以直接將SQL語句送給ODBC。

　　一個基于ODBC的應用程序對數據庫的操作不依賴任何DBMS，不直接與DBMS打交道，所有的數據庫操作由對應的DBMS的ODBC驅動程序完成。也就是說，不論是FoxPro、Access還是Oracle數據庫，均可用ODBC API進行訪問。由此可見，ODBC的最大優點是能以統一的方式處理所有的數據庫。

　　一個完整的ODBC由下列幾個部件組成：
　　　
　　1. 應用程序(Application)

　　ODBC管理器(Administrator)。該程序位于Windows 95控制面板(Control Panel)的32位ODBC內，其主要任務是管理安裝的ODBC驅動程序和管理數據源。

　　驅動程序管理器(Driver Manager)。驅動程序管理器包含在ODBC32.DLL中，對用戶是透明的。其任務是管理ODBC驅動程序，是ODBC中最重要的部件。

　　2. ODBC API

　　ODBC 驅動程序。是一些DLL，提供了ODBC和數據庫之間的接口。

　　數據源。數據源包含了數據庫位置和數據庫類型等信息，實際上是一種數據連接的抽象。

　　ODBC連接目前僅僅限于關系型數據庫，對于其他數據源比如EXCEL、文本文件都不能進行訪問，而且有很多DBMS（數據庫管理系統）都不能充分的支持其所有的功能。相比之下，OLEDB可以存取任何形式的數據，所以其功能是相當的強大，它也指導了目前技術發展的方向。

　　ADO

　　ADO（ActiveX Data Object）是DAO/RDO的后繼產物。ADO 2.0在功能上與RDO更相似，而且一般來說，在這兩種模型之間有一種相似的映射關系。ADO"擴展"了DAO和 RDO 所使用的對象模型，這意味著它包含較少的對象、更多的屬性、方法（和參數），以及事件。

　　作為最新的數據庫訪問模式，ADO的使用也是簡單易用，所以微軟已經明確表示今后把重點放在ADO上，對DAO/RDO不再作升級，所以ADO已經成為了當前數據庫開發的主流。

　　ADO涉及的數據存儲有DSN(數據源名稱)、ODBC（開放式數據連接）以及OLE DB三種方式。后面的例程將詳細講解這三種方式的具體訪問實現。

　　要使用ADO，必須清楚ADO的對象層次結構，其大體上分為以下7個對象層次：

　　1、 Command 對象：包含關于某個命令，例如查詢字符串、參數定義等的信息。Command 對象在功能上和 RDO的rdoQuery 對象相似。

　　2、 Connection 對象：包含關于某個數據提供程序的信息。Connection 對象在功能上和 RDO 的 rdoConnection 對象是相似的，并且包含了關于結構描述的信息。它還包含某些 RDOEnvironment 對象的功能，例如transaction 控件。

　　3、 Error對象：包含數據提供程序出錯時的擴展信息。Error 對象在功能上和 RDO 的rdoError 對象相似。

　　4、 Field 對象：包含記錄集中數據的某單個列的信息。Field 對象在功能上和 RDO的rdoColumn 對象相似。

　　5、 Parameter 對象：包含參數化的Command對象的某單個參數的信息。該 Command對象有一個包含其所有Parameter 對象的 Parameters 集合。Parameter 對象在功能上和 RDO 的 rdoParameter 對象相似。

　　6、 Property對象：包含某個 ADO 對象的提供程序定義的特征。沒有任何等同于該對象的RDO，但DAO有一個相似的對象。

　　7、Recordset對象：用來存儲數據操作返回的記錄集。此對象和Connection對象是所有對象最重要的兩個對象。

　　當然，對于初級用戶來說，我們只需要掌握其中的Connection對象和RecordSet對象就可以實現基本的數據庫操作，在后面的經驗介紹里面我將給出詳細的介紹。

二. 開發經驗小結：

　　前面總體上介紹了一下當前在VB平臺下的數據庫訪問技術，這些技術也是當前數據庫技術的主流。下面筆者結合近幾年的開發經驗，給出一些開發經驗和小技巧，以供參考：

　　經驗一：如果數據量不大，而且要求開發周期短的情況，建議使用DAO+Access雖然DAO功能并不強大，但是其對Jet引擎進行了加速優化處理，所以這種搭配應該是比較好的選擇。

　　經驗二：RDO當前已經用的很少了，一般用ADO來替代。

　　經驗三：（本經驗很重要）使用ADO開發時，連接數據庫的方式有三種（前面已經敘述了），其中DSN需要用戶首先使用要將所要操縱的數據庫設置為數據庫源并給其命名。方法是在控制面板－>管理工具－>數據源（ODBC）下面進行配置。比如設置的數據源名稱為data,那么可以通過下面幾行代碼來連接數據庫：

Dim conn As New ADODB.Connection
Dim rs As New ADODB.Recordset
注釋：連接數據庫
conn.Open "dsn=data"
注釋：打開數據源（即選定操作的數據對象）
rs.Open SQL語句, conn  

　　但是如果是使用ODBC和OLEDB的方式進行連接，那么大家一定知道在連接字符串上那一長串的代碼，不要說對于初學者，就是對于那些經驗豐富的程序員來說，也很難記住這一串代碼。那么如何可以記住這一串代碼呢？其實，方法很簡單，只要添加一個ADO Data控件，然后在其屬性框中使用向導進行設置后，那么最后向導就會自動生成一段ConnectionString,只需要將這一行代碼拷貝下來然后放到conn.open之后的連接字符串參數的位置上就可以了。這條經驗希望讀者能夠記住，實際開發中很實用。

　　經驗四：前面講到手動設置ODBC數據源，這里可以通過程序來進行動態設置。首先要清楚的是ODBC的詳細信息全部存放在注冊表的下述鍵值內："HKEY_LOCAL_MACHINE\SOFTWARE\ODBC"，通過調用Win32函數WriteProfileString來對相應的鍵值進行修改即可達到目的。

　　經驗五：通常將數據庫的連接代碼和資源釋放代碼放入各自特定的函數里面，因為一般大一點的程序里需要經常對這兩個功能模塊進行調用，這樣做就可以提高效率，當然很多時候都需要寫成連接池的形式。

　　經驗六：使用VB在SQL中處理含單引號的字符串時，對字符串數據都用單引號引起來，如：

Select * from MyTable Where ID=注釋：FirstID注釋：

　　若其中的FirstID為First注釋：ID，即中間多出一個單引號，則上述寫法將導致錯誤，解決的辦法是將字符串中的每一個單引號用兩雙引號替換，下面的函數StrToSQL完成該功能，并用單引號將處理后的字符串引起來：

　Private Function StrToSQL(ByVal strValue As String) As String
　　　　StrToSQL = "注釋：" + Replace(strValue, "注釋：", "注釋：注釋：") + "注釋："
　End Function

　　在寫SQL時如有字符串數據，不管其中有沒有單引號，都可以這樣使用：

　　　strValue="First注釋：Id"
　　　strSQL="Select * from MyTable Where ID="+StrToSQL(strValue)
三. 實例解析

　　下面介紹一個實例，來消化以上的相關知識。這里我在一個程序界面下實現了DAO,ADO,ODBC,OLEDB四種數據庫訪問方式。

　　程序代碼分析：

注釋：整個程序功能是選擇不同的連接方式來進行顯示工作，三種方式顯示效果完全相同
注釋：下面是主程序過程
Private Sub Command1_Click()
　Dim selitem As Integer
　注釋：判斷連接數據庫的方式
　If Option1.Value = True Then
　　selitem = 1
　Else
　　If Option2.Value = True Then
　　　selitem = 2
　　Else
　　　selitem = 3
　　End If
　End If

　注釋：選取不同的數據庫連接方式
　Select Case selitem
　Case 1:
　　注釋：使用DAO的數據庫連接方式
　　Call ShowByDAO
　Case 2:
　　注釋：使用ADO的數據庫連接方式
　　Call ShowByADO
　Case 3:
　　注釋：使用ODBC的數據庫連接方式
　　Call ShowByODBC
　Case 4:
　　注釋：使用OLEDB的數據庫連接方式
　　Call ShowByOLEDB
　End Select
End Sub

Private Sub ShowByDAO()
　注釋：使用DAO的數據庫連接方式
　Dim db As Database
　Dim rs As Recordset
　Dim sqlstr$ 注釋：存放查詢語句
　Set db = OpenDatabase(App.Path & "\db1.mdb")
　sqlstr = "select * from 成績表"
　Set rs = db.OpenRecordset(sqlstr)
　注釋：顯示結果
　Call GridShow(rs)
End Sub

Sub ShowByADO()
　Dim conn As New ADODB.Connection
　Dim rs As New ADODB.Recordset
　注釋：使用數據源來連接數據庫
　conn.Open "dsn=data"
　rs.CursorType = adOpenKeyset
　rs.LockType = adLockOptimistic
　rs.Open "select * from 成績表", conn
　Call GridShowOfADO(rs)
End Sub

Sub ShowByODBC()
　Dim conn As New ADODB.Connection
　Dim rs As New ADODB.Recordset
　注釋：使用數據源來連接數據庫
　conn.Open "Provider=MSDASQL.1;Persist Security Info=False;Data Source=data"
　rs.Open "select * from 成績表", conn
　注釋：顯示結果
　Call GridShowOfADO(rs)
End Sub

Sub ShowByOLEDB()
　Dim conn As New ADODB.Connection
　Dim rs As New ADODB.Recordset
　注釋：使用數據源來連接數據庫
　conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" + App.Path & "\db1.mdb" + ";Persist Security Info=False"
　rs.Open "select * from 成績表", conn

　注釋：顯示結果
　Call GridShowOfADO(rs)
End Sub

Sub GridShow(rs As Recordset)
　注釋：對dao方式進行顯示工作
　MSFlexGrid1.TextMatrix(0, 0) = "姓名"
　MSFlexGrid1.TextMatrix(0, 1) = "性別"
　MSFlexGrid1.TextMatrix(0, 2) = "語文"
　MSFlexGrid1.TextMatrix(0, 3) = "數學"
　MSFlexGrid1.TextMatrix(0, 4) = "英語"
　rs.MoveLast
　MSFlexGrid1.Rows = rs.RecordCount + 1
　MSFlexGrid1.Cols = rs.Fields.Count
　Dim i%
　i = 1
　rs.MoveFirst
　While (Not rs.EOF)

　　MSFlexGrid1.TextMatrix(i, 0) = rs.Fields(0)
　　MSFlexGrid1.TextMatrix(i, 1) = rs.Fields(1)
　　MSFlexGrid1.TextMatrix(i, 2) = rs.Fields(2)
　　MSFlexGrid1.TextMatrix(i, 3) = rs.Fields(3)
　　MSFlexGrid1.TextMatrix(i, 4) = rs.Fields(4)
　　rs.MoveNext
　　i = i + 1
　　注釋：If (rs.EOF = True) Then
　　注釋： Exit For
　Wend
End Sub

Sub GridShowOfADO(rs As ADODB.Recordset)
　注釋：對ado方式進行顯示工作
　MSFlexGrid1.TextMatrix(0, 0) = "姓名"
　MSFlexGrid1.TextMatrix(0, 1) = "性別"
　MSFlexGrid1.TextMatrix(0, 2) = "語文"
　MSFlexGrid1.TextMatrix(0, 3) = "數學"
　MSFlexGrid1.TextMatrix(0, 4) = "英語"
　注釋：注意recordcount屬性必須在當前記錄指針在最后一條記錄時才會返回正確的值
　rs.MoveLast
　MSFlexGrid1.Rows = rs.RecordCount + 1
　MSFlexGrid1.Cols = rs.Fields.Count
　Dim i%
　i = 1
　rs.MoveFirst
　While (Not rs.EOF)
　　MSFlexGrid1.TextMatrix(i, 0) = rs.Fields(0)
　　MSFlexGrid1.TextMatrix(i, 1) = rs.Fields(1)
　　MSFlexGrid1.TextMatrix(i, 2) = rs.Fields(2)
　　MSFlexGrid1.TextMatrix(i, 3) = rs.Fields(3)
　　MSFlexGrid1.TextMatrix(i, 4) = rs.Fields(4)
　　rs.MoveNext
　　i = i + 1
　Wend
End Sub

Private Sub Command2_Click()
End
End Sub

　　上述代碼已經在Windows 2000 professional和Visual Basic 6.0的環境下調試成功。

四.小結

　　本文通過對數據庫訪問相關技術的分析與總結，提出若干有價值的經驗。借鑒這些經驗，會給開發帶來一定的便利。