DECLARE @Date DATETIME
SET @Date=GETDATE()
--前一天，給定日期的前一天
SELECT DATEADD(DAY,-1,@Date) AS '前一天'
--后一天，給定日期的后一天
SELECT DATEADD(DAY,1,@Date) AS '后一天'
GO
--月初，計(jì)算給定日期所在月的第一天
--這個(gè)計(jì)算的技巧是先計(jì)算當(dāng)前日期到“1900-01-01”的時(shí)間間隔數(shù)，然后把它加到“1900-01-01”上來(lái)獲得特殊的日期，這個(gè)技巧可以用---來(lái)計(jì)算很多不同的日期。
DECLARE @Date DATETIME
SET @Date=GETDATE()
SELECT DATEADD(MONTH,DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01') AS '所在月的第一天'
--精簡(jiǎn)算法，根據(jù)SQL Server的時(shí)間表示方式可知，'1900-01-01' 可以用0代替
SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0) AS '所在月的第一天'
--上面兩種算法精確到天 時(shí)分秒均為00:00:00.000
--下面算法課以保留時(shí)分秒
--思路：用給定日期減去月第一天與給定日期差的天數(shù)
SELECT DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)
GO
--月末，計(jì)算給定日期所在月的最后一天
DECLARE @Date DATETIME
SET @Date=GETDATE()
--思路：當(dāng)前月的下一月1號(hào)在減1天
SELECT DATEADD(DAY,-1,DATEADD(MONTH,1+DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01')) AS '所在月的最一天'
SELECT DATEADD(MONTH,1+DATEDIFF(MONTH,'1900-01-01',@Date),'1900-01-01')-1 AS '所在月的最一天'
--1900-01-01 用0代替
SELECT DATEADD(DAY,-1,DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0)) AS '所在月的最一天'
SELECT DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0)-1 AS '所在月的最一天'
--思路：與月初計(jì)算思路相同
SELECT DATEADD(MONTH,DATEDIFF(MONTH,'1989-12-31',@Date),'1989-12-31') AS '所在月的最一天'
--精簡(jiǎn)算法，'1989-12-31' 用-1代替
SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date),-1) AS '所在月的最一天'
--保留時(shí)分秒的算法
SELECT DATEADD(DAY,-1,DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)))
GO
--其他月計(jì)算
--計(jì)算給定日期所在月的上月第一天
DECLARE @Date DATETIME
SET @Date=GETDATE()
--當(dāng)前月第一天減去一個(gè)月
SELECT DATEADD(MONTH,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '上月第一天'
--簡(jiǎn)化
SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)-1,0) AS '上月第一天'
--另一種當(dāng)前月第一天算法
SELECT DATEADD(MONTH,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月第一天'
GO
--計(jì)算給定日期所在月的上月最后一天
DECLARE @Date DATETIME
SET @Date=GETDATE()
--當(dāng)前月第一天減去一天
SELECT DATEADD(DAY,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '上月最后一天'
--另一種當(dāng)前月第一天算法
SELECT DATEADD(DAY,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月最后一天'
SELECT DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)-1 '上月最后一天'
--另一種算法，不能用當(dāng)前月的最后一天加一個(gè)月，因?yàn)楫?dāng)前月可能是30天。
--例如 SELECT DATEADD(MONTH,1,'2010-06-30') --結(jié)果是2010-07-30而不是2010-07-31，
--這也是月末算法采用下月第一天減1天計(jì)算的原因
--但是如果計(jì)算月是31天擇無(wú)此問(wèn)題
--例如 SELECT DATEADD(MONTH,1,'2010-05-31') --結(jié)果是2010-06-30
--因此下面算法是正確的，-1 表示'1899-12-31 00:00:00.000'-- SELECT CONVERT(DATETIME,-1)
SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date)-1,-1)
--另一種當(dāng)前月算法
SELECT DATEADD(DAY,-1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '上月最后一天'
--簡(jiǎn)化
SELECT DATEADD(DAY,0-DATEPART(DAY,@Date),@Date) '上月最后一天'
GO
--計(jì)算給定日期所在月的下月第一天
DECLARE @Date DATETIME
SET @Date=GETDATE()
--當(dāng)前月第一天加一個(gè)月
SELECT DATEADD(MONTH,1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0)) AS '下月第一天'
--簡(jiǎn)化
SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+1,0) AS '下月第一天'
--另一種當(dāng)前月第一天算法
SELECT DATEADD(MONTH,1,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date)) '下月第一天'
GO
--計(jì)算給定日期所在月的下月最后一天
DECLARE @Date DATETIME
SET @Date=GETDATE()
--當(dāng)前月第一天加2個(gè)月再減去1天
SELECT DATEADD(DAY,-1,DATEADD(MONTH,2,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0))) AS '下月最后一天'
--簡(jiǎn)化
SELECT DATEADD(DAY,-1,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+2,0)) AS '下月最后一天'
SELECT DATEADD(MONTH,DATEDIFF(MONTH,0,@Date)+2,0)-1 AS '下月最后一天'
--另一種算法
SELECT DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date)+1,-1) '下月最后一天'
--另一種當(dāng)前月第一天算法
SELECT DATEADD(DAY,-1,DATEADD(MONTH,2,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date))) '下月最后一天'
GO
--所在星期的第一天，計(jì)算給定日期所在星期的第1天(星期日為第一天)
DECLARE @Date DATETIME
SET @Date= GETDATE()
--與SQL Server語(yǔ)言版本相關(guān)的算法
--思路：當(dāng)前日期+星期日(每周的第1天)與當(dāng)前日期的差的天數(shù)
--DATEPART(WEEKDAY,DATE)的返回值與@@DATEFIRST相關(guān)
SET DATEFIRST 7 -- 或者設(shè)置為美國(guó)英語(yǔ)SET LANGUAGE us_english; (星期日為第一天)
SELECT DATEADD(WEEKDAY,1-DATEPART(WEEKDAY,@Date),@Date) AS '所在星期的第一天，星期日'
--星期日，與SQL Server語(yǔ)言版本或@@DATEFIRST無(wú)關(guān)
--'1989-12-31' 是星期日，'1989-12-31' 再加上(當(dāng)前日期與1989-12-31差的星期數(shù))個(gè)星期
SELECT DATEADD(WEEK,DATEDIFF(WEEK,-1,@Date),-1) AS '所在星期的星期日'
--或者
SELECT DATEADD(WEEK,DATEDIFF(WEEK,6,@Date),6) AS '所在星期的星期日'
GO
--所在星期的第二天，計(jì)算給定日期所在星期的第2天(星期日為第一天)
DECLARE @Date DATETIME
SET @Date= GETDATE()
--思路：當(dāng)前日期+星期一(每周的第2天)與當(dāng)前日期的差的天數(shù)
--DATEPART(WEEKDAY,DATE)的返回值與@@DATEFIRST相關(guān)
SET DATEFIRST 7 -- 或者設(shè)置為美國(guó)英語(yǔ)SET LANGUAGE us_english; (星期日為第一天)
SELECT DATEADD(DAY,2-DATEPART(WEEKDAY,@Date),@Date) AS '所在星期的第二天，星期一'
--星期一，與SQL Server語(yǔ)言版本或@@DATEFIRST無(wú)關(guān)
--'1900-01-01' 是星期一，'1900-01-01' 再加上(當(dāng)前日期與1900-01-01差的星期數(shù))個(gè)星期
SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,@Date),0) AS '所在星期的星期一'
GO
--上個(gè)星期第一天，計(jì)算給定日期所在星期的上一個(gè)星期日(星期日為第一天)
DECLARE @Date DATETIME
SET @Date= GETDATE()
--思路：當(dāng)前日志所在星期的星期日再減1周
--DATEPART(WEEKDAY,DATE)的返回值與@@DATEFIRST相關(guān)
SET DATEFIRST 7 -- 或者設(shè)置為美國(guó)英語(yǔ)SET LANGUAGE us_english; (星期日為第一天)
SELECT DATEADD(WEEK,-1,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '上個(gè)星期第一天，星期日'
--一周等于7天
SELECT DATEADD(DAY,-7,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '上個(gè)星期第一天，星期日'
--簡(jiǎn)化
SELECT DATEADD(DAY,-6-DATEPART(WEEKDAY,@Date),@Date) AS '上個(gè)星期第一天，星期日'
--上個(gè)星期日，與SQL Server語(yǔ)言版本或@@DATEFIRST無(wú)關(guān)
SELECT DATEADD(WEEK,-1+DATEDIFF(WEEK,-1,@Date),-1) AS '上個(gè)星期日'
--或者
SELECT DATEADD(WEEK,DATEDIFF(WEEK,6,@Date),-1) AS '上個(gè)星期日'
GO
--下個(gè)星期第一天，計(jì)算給定日期所在星期的下一個(gè)星期日(星期日為第一天)
DECLARE @Date DATETIME
SET @Date= GETDATE()
--思路：當(dāng)前日志所在星期的星期日再加1周
--DATEPART(WEEKDAY,DATE)的返回值與@@DATEFIRST相關(guān)
SET DATEFIRST 7 -- 或者設(shè)置為美國(guó)英語(yǔ)SET LANGUAGE us_english; (星期日為第一天)
SELECT DATEADD(WEEK,1,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '下個(gè)星期第一天，星期日'
--一周等于7天
SELECT DATEADD(DAY,7,DATEADD(DAY,1-DATEPART(WEEKDAY,@Date),@Date)) AS '下個(gè)星期第一天，星期日'
--簡(jiǎn)化
SELECT DATEADD(DAY,8-DATEPART(WEEKDAY,@Date),@Date) AS '下個(gè)星期第一天，星期日'
--下個(gè)星期日，與SQL Server語(yǔ)言版本或@@DATEFIRST無(wú)關(guān)
SELECT DATEADD(WEEK,1+DATEDIFF(WEEK,-1,@Date),-1) AS '下個(gè)星期日'
--或者
SELECT DATEADD(WEEK,DATEDIFF(WEEK,-1,@Date),6) AS '下個(gè)星期日'
GO
--判斷給定日期是星期幾
DECLARE @Date DATETIME
SET @Date= GETDATE()
--DATEPART(WEEKDAY,DATE)的返回值與@@DATEFIRST相關(guān)
SET DATEFIRST 7 -- 或者設(shè)置為美國(guó)英語(yǔ)SET LANGUAGE us_english; (星期日為第一天)
SELECT DATEPART(WEEKDAY,@Date) --返回值 1-星期日，2-星期一，3-星期二......7-星期六
--上面算法與SQL 語(yǔ)言版本或 @@DATEFIRST 相關(guān)
--下面算法與SQL Server語(yǔ)言版本或@@DATEFIRST無(wú)關(guān)
SELECT DATENAME(WEEKDAY,@Date) '星期'
GO
--年度計(jì)算
DECLARE @Date DATETIME
SET @Date=GETDATE()
--年初，計(jì)算給定日期所在年的第一天
SELECT DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0) AS '所在年的第一天'
--年末，計(jì)算給定日期所在年的最后一天
SELECT DATEADD(YEAR,DATEDIFF(YEAR,-1,@Date),-1) AS '所在年的最后一天'
--上一年年初，計(jì)算給定日期所在年的上一年的第一天
SELECT DATEADD(YEAR,DATEDIFF(YEAR,-0,@Date)-1,0) AS '所在年的上一年的第一天'
--上一年年末，計(jì)算給定日期所在年的上一年的最后一天
SELECT DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1) AS '所在年的上一年的最后一天'
--下一年年初，計(jì)算給定日期所在年的下一年的第一天
SELECT DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0) AS '所在年的下一年的第一天'
--下一年年末，計(jì)算給定日期所在年的下一年的最后一天
SELECT DATEADD(YEAR,1+DATEDIFF(YEAR,-1,@Date),-1) AS '所在年的下一年的最后一天'
GO
--季度計(jì)算
DECLARE @Date DATETIME
SET @Date=GETDATE()
--季度初，計(jì)算給定日期所在季度的第一天
SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0) AS '當(dāng)前季度的第一天'
--季度末，計(jì)算給定日期所在季度的最后一天
SELECT DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),-1) AS '當(dāng)前季度的最后一天'
--上個(gè)季度初
SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date)-1,0) AS '當(dāng)前季度的上個(gè)季度初'
--上個(gè)季度末
SELECT DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),-1) AS '當(dāng)前季度的上個(gè)季度末'
--下個(gè)季度初
SELECT DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),0) AS '當(dāng)前季度的下個(gè)季度初'
--下個(gè)季度末
SELECT DATEADD(QUARTER,2+DATEDIFF(QUARTER,0,@Date),-1) AS '當(dāng)前季度的下個(gè)季度末'
GO
--計(jì)算給定日期所在月的天數(shù)
DECLARE @Date DATETIME;
SET @Date = GETDATE()
--本月度第一天與下月度第一天所差的天數(shù)
SELECT DATEDIFF(DAY,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0),DATEADD(MONTH,1+DATEDIFF(MONTH,0,@Date),0))
--借助變量簡(jiǎn)化
SELECT @Date = DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0) --本月度第一天
SELECT DATEDIFF(DAY,@Date,DATEADD(MONTH,1,@Date))
--另一種思路：給定月最后一天的日期，記為本月天數(shù)
SELECT DAY(DATEADD(MONTH,DATEDIFF(MONTH,-1,@Date),-1))
GO
--計(jì)算給定日期所在季度的天數(shù)
DECLARE @Date DATETIME;
SET @Date = GETDATE()
--本季度第一天與下季度第一天所差的天數(shù)
SELECT DATEDIFF(DAY,DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0),DATEADD(QUARTER,1+DATEDIFF(QUARTER,0,@Date),0))
--借助變量簡(jiǎn)化
SELECT @Date = DATEADD(QUARTER,DATEDIFF(QUARTER,0,@Date),0) --本季度第一天
SELECT DATEDIFF(DAY,@Date,DATEADD(QUARTER,1,@Date))
GO
--計(jì)算給定日期所在年度的天數(shù)
DECLARE @Date DATETIME;
SET @Date = GETDATE()
--本年度第一天與下年度第一天所差的天數(shù)
SELECT DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0),DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0))
--借助變量簡(jiǎn)化
SELECT @Date = DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0) --本年度第一天
SELECT DATEDIFF(DAY,@Date,DATEADD(YEAR,1,@Date))
GO
--判斷給定日期所在年是否閏年
--根據(jù)全年總天數(shù)判斷
DECLARE @Date DATETIME;
SET @Date = GETDATE()
SELECT CASE DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),0),DATEADD(YEAR,1+DATEDIFF(YEAR,0,@Date),0))
WHEN 365 THEN '平年' ELSE '閏年' END
--根據(jù)二月天數(shù)判斷
--給日期的上一年最后一天加2個(gè)月，即為當(dāng)年2月最后一天
SELECT CASE DAY(DATEADD(MONTH,2,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1))) WHEN 28 THEN '平年' ELSE '閏年' END
GO
--計(jì)算給定日期是當(dāng)年的第幾天
DECLARE @Date DATETIME;
SET @Date = GETDATE()
SELECT DATEPART(DAYOFYEAR,@Date) [DayOfYear];
SELECT DATENAME(DAYOFYEAR,@Date) [DayOfYear];
--另一種思路：當(dāng)前日期與上年最后一天差的天數(shù)
SELECT DATEDIFF(DAY,DATEADD(YEAR,DATEDIFF(YEAR,0,@Date),-1),@Date)[DayOfYear]
GO
--計(jì)算給定日期是當(dāng)年的第幾周
DECLARE @Date DATETIME;
SET @Date = GETDATE()
SELECT DATEPART(WEEK,@Date) [WeekOfYear]; --返回int型
SELECT DATENAME(WEEK,@Date) [WeekOfYear]; --返回varchar型
GO
--計(jì)算給定日期是當(dāng)年的第幾月
DECLARE @Date DATETIME;
SET @Date = GETDATE()
SELECT DATEPART(MONTH,@Date) [MonthOfYear]; --返回int型
SELECT DATENAME(MONTH,@Date) [MonthOfYear]; --返回varchar型
SELECT MONTH(@Date) [MonthOfYear];--返回int型
GO
--計(jì)算給定日期是當(dāng)年的第幾季度
DECLARE @Date DATETIME;
SET @Date = GETDATE()
SELECT DATEPART(QUARTER,@Date) [QuarterOfYear]; --返回intb型
SELECT DATENAME(QUARTER,@Date) [QuarterOfYear]; --返回varchar型
GO
--計(jì)算給定日期是當(dāng)月的第幾周
DECLARE @Date DATETIME;
SET @Date = GETDATE()
--tb思路，給定日期是當(dāng)年的第幾周-給定日期所在月第一天是當(dāng)年的第幾周
SELECT DATEPART(WEEK,@Date)-DATEPART(WEEK,DATEADD(MONTH,DATEDIFF(MONTH,0,@Date),0))+1 [WeekOfMonth]
SELECT DATEPART(WEEK,@Date)-DATEPART(WEEK,DATEADD(DAY,1-DATEPART(DAY,@Date),@Date))+1 [WeekOfMonth]
GO
--計(jì)算給定日期所在月的第一個(gè)星期一是哪天
DECLARE @Date DATETIME;
SET @Date = GETDATE()
--思路，1900-01-01(星期一)加上(給定日志所在月的月6號(hào)與1900-01-01差的周數(shù))個(gè)周
--為什么不選7號(hào)？如果是7號(hào)，那么7好恰好是星期日的話，第一個(gè)周一就會(huì)算到8號(hào)。
--為什么不選5號(hào)？如果5號(hào)是星期六，那么周一就跑到上月了。小于5號(hào)與這個(gè)道理一樣。
SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),0) '所在月的第一個(gè)星期一'
SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),7) '所在月的第二個(gè)星期一'
SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),1) '所在月的第一個(gè)星期二'
SELECT DATEADD(WEEK,DATEDIFF(WEEK,0,DATEADD(DAY,6-DATEPART(DAY,@Date),@Date)),8) '所在月的第二個(gè)星期二'
GO