版本控制最關鍵的一件事是保證數據的安全性，不能因為磁盤損壞，程序故障造成版本庫無可挽回的錯誤，為此必須制定較完備的備份策略。在Subversion中，我們有三種備份方式：完全備份，增量備份和同步版本庫。

1, 完全備份

最常見和簡單的備份就是直接使用拷貝命令，將版本庫目錄拷貝到備份目錄上，就可以了。但是這樣不是很安全的方式，因為如果在拷貝時版本庫發生變化，將會造成備份的結果不夠準確，失去備份的作用，為此Subversion提供了“svnadmin hotcopy”命令，可以防止這種問題。

還記得我們的版本庫目錄嗎？

D:\SVNROOT
├─project1
│? ├─conf
│? ├─dav
│? ├─db
│? │? ├─revprops
│? │? ├─revs
│? │? └─transactions
│? ├─hooks
│? └─locks
└─project2
??? ├─conf
??? ├─dav
??? ├─db
??? │? ├─revprops
??? │? ├─revs
??? │? └─transactions
??? ├─hooks
??? └─locks
???

如果要把project1備份到d:\svnrootbak目錄下，只需要運行：

svnadmin hotcopy d:\svnroot\project1 d:\svnrootbak\project1

但是我們作為配置管理員，必須想辦法優化這個過程，如果我們這個目錄下有許多版本庫，需要為每個版本庫寫這樣一條語句備份，為此我寫了下面的腳本，實現備份一個目錄下的所有版本庫。我們在D:\SVNROOT下創建了兩個文件，simpleBackup.bat：

@echo 正在備份版本庫%1......
@%SVN_HOME%\bin\svnadmin hotcopy %1 %BACKUP_DIRECTORY%\%2
@echo 版本庫%1成功備份到了%2！

這個文件僅僅是對“svnadmin hotcopy”的包裝，然后是backup.bat：

echo off

rem Subversion的安裝目錄
set SVN_HOME="D:\Subversion"

rem 所有版本庫的父目錄
set SVN_ROOT=D:\svnroot

rem 備份的目錄
set BACKUP_SVN_ROOT=D:\svnrootbak

set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~0,10%
if exist %BACKUP_DIRECTORY% goto checkBack
echo 建立備份目錄%BACKUP_DIRECTORY%>>%SVN_ROOT%/backup.log

mkdir %BACKUP_DIRECTORY%

rem 驗證目錄是否為版本庫，如果是則取出名稱備份
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I\conf\svnserve.conf" %SVN_ROOT%\simpleBackup.bat "%%~fI" %%~nI
goto end

:checkBack
echo 備份目錄%BACKUP_DIRECTORY%已經存在，請清空。
goto end

:end

你在使用的時候，只需要修改backup.bat開頭的三個路徑，將兩個腳本拷貝到“SVN_ROOT”下就可以了。根據以上的配置，你只需要運行backup.bat，就可以把“SVN_ROOT”下的版本庫都備份到“BACKUP_SVN_ROOT”里，并且存放在備份所在日的目錄里，例如“D:\svnrootbak\2006-10-22”。

雖然這部分工作很簡單，可是必須有人定時地去執行這個操作（例如每周一凌晨），為了避免發生遺忘的情況，我們可以將這個操作加入到系統的at任務當中去，例如還是上面的環境，為了安裝at任務，我們運行：

at 1:00 /every:M D:\svnroot\backup.bat

這樣在每周一凌晨1:00都會執行這個備份過程。當然備份在本機也是不安全的，你也許需要上傳到別的機器，這個就要靠你自己去實現了。

2, 增量備份

盡管完全備份非常簡單，但是也是有代價的，當版本庫非常巨大時，經常進行完全備份是不現實的，也并不必要，但是一旦版本庫在備份之間發生問題，該如何呢，這里我們就用到了增量備份。

增量備份通常要與完全備份結合使用，就像oracle數據庫的歸檔日志，記錄著每次Subversion提交的變化，然后在需要恢復時能夠回到最新的可用狀態。在我們這個例子中我們使用的是，svnadmin dump命令進行增量的備份，使用方法是：

svnadmin dump?project1?--revision 15 --incremental > dumpfile2

上面的命令實現了對修訂版本15進行增量的備份，其中的輸出文件dumpfile2只保存了修訂版本15更改的內容。

為了記錄每次提交的結果，我們需要使用一項Subversion的特性--鉤子（hook），看看我們的project1目錄：

├─project1
│? ├─conf
│? ├─dav
│? ├─db
│? │? ├─revprops
│? │? ├─revs
│? │? └─transactions
│? ├─hooks
│? └─locks

其中的hooks目錄里存放的就是鉤子腳本，我們在此處只使用post-commit鉤子，這個鉤子會在每次提交之后執行，為了實現我們的備份功能，我們在hooks下建立一個文件post-commit.bat，內容如下：

echo off
set SVN_HOME="C:\Program Files\Subversion"
set SVN_ROOT=D:\svnroot
set UNIX_SVN_ROOT=D:/svnroot
set DELTA_BACKUP_SVN_ROOT=D:\svnrootbak\delta

set LOG_FILE=%1\backup.log
echo backup revision %2 >> %LOG_FILE%

for /r %SVN_ROOT% %%I in (.) do if D:/svnroot/%%~nI == %1 %SVN_ROOT%\%%~nI\hooks\deltaBackup.bat %%~nI %2
goto end

:end

通過這個腳本，可以實現D:\svnroot下的版本庫提交時自動增量備份到D:\svnrootbak\delta（確定這個目錄存在），其中使用的deltaBackup.bat其實可以放在任何地方，只是對腳本的svnadmin dump的包裝，內容如下：

@echo 正在備份版本庫%2......
%SVN_HOME%\bin\svnadmin dump %SVN_ROOT%\%1 --incremental --revision %2 >> %DELTA_BACKUP_SVN_ROOT%\%1.dump
@echo 版本庫%2成功備份到了%3！

以上兩個腳本可以直接拷貝到project2的hooks目錄下，不需要修改就可以實現project2的自動備份。

以上的操作已經OK了，現在需要做的是將完全備份和增量備份結合起來，也就是在完全備份后清理增量備份的結果，使之只保存完全備份后的結果。

當果真出現版本庫的故障，就要求我們實現版本庫的恢復操作了，這是用要使用svnadmin load命令，同時也需要上次的完全備份例如要把上次完全備份backuprepo，和之后的增量備份dumpfile：

svnadmin load?backuprepo < dumpfile

最后的結果，可以下載svnroot.rar，將之解壓縮到d:\下，然后修改幾個bat文件的SVN_HOME就可以使用了。

3, 版本庫同步

Subversion 1.4增加了同步機制，可以實現一個版本庫同另一個版本庫的同步（但好像只是單向的），我們可以用來實現版本庫的備份或鏡像。

3.1. 對目標庫初始化

svnsync init svn://localhost/project2 svn://localhost/project1 
?

其中project2是目標的版本庫，而project1是源版本庫。其中的目標版本庫必須為空，而且必須允許修訂版本屬性的修改，也就是在目標的版本庫的hooks目錄里添加一個文件pre-revprop-change.bat，內容為空即可。

3.2. 同步project2到project1

svnsync sync svn://localhost/project2 
?

這時候你update一下你的project2的一個工作拷貝，就會發現有了project1的所有內容。如果project1又有提交，這時候project2的版本庫無法看到最新的變化，還需要再運行一遍sync操作，這樣才能將最新的變化同步。需要注意的是，目標版本庫只能做成只讀的，如果目標版本庫發生了變更，則無法繼續同步了。

3.3. 同步歷史屬性的修改

因為同步不會更新對歷史屬性的修改，所以svnsync還有子命令copy-revprops，可以同步某個版本的屬性。

3.4. 鉤子自動同步

希望在每次提交時同步，則需要在源版本庫增加post-commit腳本，內容如下：

						
								echo
						 off
set SVN_HOME="D:\Subversion"
%SVN_HOME%\bin\svnsync sync  --non-interactive svn://localhost/project2 
?

把以上內容存放為post-commit.bat，然后放到版本庫project1下的hooks目錄下，這樣project1每次提交，都會引起project2的同步。