SETLOCAL

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 設置初始變量
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SET FileName=預防Autorun病毒

SET FilePath=%ProgramFiles%\\%FileName%.bat

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 如果原來有BAT文件就先取消所有屬性，方便下面的修改
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST "%FilePath%" ATTRIB -S -H -A -R "%FilePath%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 生成BAT文件并存放到指定地點
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: 先刪除帶路人AUTORUN.INF，注意防止AUTORUN.INF是文件夾>"%FilePath%"
ECHO @IF NOT EXIST AUTORUN.INF\ ATTRIB -S -H -A -R AUTORUN.INF>>"%FilePath%"
ECHO @DEL /F /Q AUTORUN.INF>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO :: 設置初始變量>>"%FilePath%"
ECHO @SET FileType=EXE,COM,PIF,LNK,386,VXD,BIN,BAT,CMD,JS,JSE,VBE,VBS,WSF,WSH,HTA,HTT,CHM,HLP,EML,FND,INF,INI,REG,KEY,MSC,MSI,SCF,SCR,SYS>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO :: 將隱藏的危險文件顯示出來>>"%FilePath%"
ECHO @FOR %%%%a IN ( %%FileType%% ) DO @ATTRIB -S -H -A -R *.%%%%a 2^>NUL>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO @ECHO.>>"%FilePath%"
ECHO @ECHO 當前根目錄下所有危險文件已經顯示，該殺該剮由你處理。>>"%FilePath%"
ECHO @ECHO.>>"%FilePath%"
ECHO @ECHO 記住，千萬別雙擊！用拖選的方式選擇要刪除的危險文件。>>"%FilePath%"
ECHO @ECHO.>>"%FilePath%"

ECHO.>>"%FilePath%"
ECHO.>>"%FilePath%"

ECHO @PAUSE>>"%FilePath%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 將BAT文件設置系統、存檔、只讀屬性
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF EXIST "%FilePath%" ATTRIB +S +A +R "%FilePath%"

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 生成注冊表文件，并且追加進注冊表中
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO Windows Registry Editor Version 5.00>AddRegister.reg

ECHO.>>AddRegister.reg

ECHO [-HKEY_CLASSES_ROOT\Drive\Shell\%FileName%]>>AddRegister.reg

ECHO.>>AddRegister.reg

ECHO [HKEY_CLASSES_ROOT\Drive\Shell\%FileName%\Command]>>AddRegister.reg
ECHO @="%FilePath%">>AddRegister.reg

REGEDIT /S AddRegister.reg

DEL /F /Q AddRegister.reg

ENDLOCAL

?

后記：

現在關于U盤病毒的防止有很多種，按Shift，或在組策略中禁止自動運行。

開始想用FINDSTR.EXE分析Autorun.inf文件，然后根據找到的路徑直接刪除病毒，但是限制條件怪多的，如真假路徑，雙執行文件，隱藏目錄，想想還是預防為主，順便鄙視一下Micro$oft！

?