感謝下面文章作者，多謝你們的經驗分享！
SQLServer2005里怎樣對使用with encryption選項創建的存儲過程解密 (推薦)
[原創]關于對SQL2005加密存儲過程的破解
如何查看sqlserver2005的加密存儲過程？具體如何操作
Sql Server 2005 專用管理員連接 (DAC) 使用技巧
1. [轉]使用DAC（專用管理員連接）連接到數據庫
在“連接到數據庫引擎”對話框的“服務器名稱”框中，鍵入 ADMIN:，并在其后繼續鍵入服務器實例的名稱。例如，若要連接到名為 ACCT\PAYABLE 的服務器實例，請鍵入 ADMIN:ACCT\PAYABLE。
注1：
無法連接到 ADMIN:WIN-SV3NUJLD0C5\MSSQLSERVER_NEW
在與 SQL Server 建立連接時出現與網絡相關的或特定于實例的錯誤。未找到或無法訪問服務器。請驗證實例名稱是否正確并且 SQL Server 已配置為允許遠程連接。 (provider: SQL 網絡接口, error: 43 - 在獲取專用的管理員連接(DAC)端口時出錯。 確保正在運行 SQL 瀏覽器，或檢查錯誤日志中是否有該端口號) (.Net SqlClient Data Provider)
------------------------------
有關幫助信息，請單擊: http://go.microsoft.com/fwlink?ProdName=Microsoft+SQL+Server&EvtSrc=MSSQLServer&EvtID=-1&LinkId=20476
原因可能是：
The firewall on the server has refused the connection.
A specified SQL Server instance name is not valid.
The SQL Server Browser service (sqlbrowser) is not started.（打開Sql Server里的 SQL Server Brower 數據庫瀏覽服務）
注2：
無法連接到 ADMIN:192.168.1.100
不支持專用管理員連接。 (ObjectExplorer)
如何啟用遠程DAC連接？
只有 SQL Server sysadmin 角色的成員可以使用 DAC 連接。默認情況下，只能從服務器上運行的客戶端建立連接。除非通過 sp_configure 使用 remote admin connections 選項進行配置，否則不允許使用網絡連接。
DAC 支持加密和 SQL Server 的其他安全性功能。DAC 只允許將用戶上下文切換到其他管理用戶。
默認情況下，DAC 僅偵聽環回 IP 地址 (127.0.0.1) 端口 1434。
remote admin connections 設置的可能值如下：
0 - 指明僅允許本地連接使用 DAC
1 - 指明允許遠程連接使用 DAC
--啟用遠程DAC連接
sp_configure 'remote admin connections', 1;
GO
RECONFIGURE;
GO
注意：配置遠程管理連接之后，會立即啟用 DAC 偵聽器而不必重新啟動 SQL Server，并且客戶端可以立即遠程連接到 DAC
2. [轉]具體解密代碼
create PROCEDURE [dbo].[sp__windbi$decrypt]
(@procedure sysname = NULL, @revfl int = 1)
AS
/*
王成輝翻譯整理，轉貼請注明出自微軟BI開拓者www.windbi.com
目前這個存儲過程只能解密存儲過程，至于解密函數、觸發器、視圖的存儲過程本網站會進一步關注，調用形式為：
exec dbo.sp__windbi$decrypt @procedure,0
如果第二個參數使用1的話，會給出該存儲過程的一些提示。
--版本2.0
*/
SET NOCOUNT ON
IF @revfl = 1
BEGIN
PRINT '警告：該存儲過程會刪除并重建原始的存儲過程。'
PRINT ' 在運行該存儲過程之前確保你的數據庫有一個備份。'
PRINT ' 該存儲過程通常應該運行在產品環境的一個備份的非產品環境下。'
PRINT ' 為了運行這個存儲過程，將參數@refl的值更改為0。'
RETURN 0
END
DECLARE @intProcSpace bigint, @t bigint, @maxColID smallint,@intEncrypted
tinyint,@procNameLength int
select @maxColID = max(subobjid),@intEncrypted = imageval FROM
sys.sysobjvalues WHERE objid = object_id(@procedure)
GROUP BY imageval
--select @maxColID as 'Rows in sys.sysobjvalues'
select @procNameLength = datalength(@procedure) + 29
DECLARE @real_01 nvarchar(max)
DECLARE @fake_01 nvarchar(max)
DECLARE @fake_encrypt_01 nvarchar(max)
DECLARE @real_decrypt_01 nvarchar(max),@real_decrypt_01a nvarchar(max)
declare @objtype varchar(2),@ParentName nvarchar(max)
select @real_decrypt_01a = ''
--提取對象的類型如是存儲過程還是函數，如果是觸發器，還要得到其父對象的名稱
select @objtype=type,@parentname=object_name(parent_object_id)
from sys.objects where [object_id]=object_id(@procedure)
-- 從sys.sysobjvalues里提出加密的imageval記錄
SET @real_01=(SELECT top 1 imageval FROM sys.sysobjvalues WHERE objid =
object_id(@procedure) and valclass = 1 order by subobjid)
--創建一個臨時表
create table #output ( [ident] [int] IDENTITY (1, 1) NOT NULL ,
[real_decrypt] NVARCHAR(MAX) )
--開始一個事務，稍后回滾
BEGIN TRAN
--更改原始的存儲過程，用短橫線替換
if @objtype='P'
SET @fake_01='ALTER PROCEDURE '+ @procedure +' WITH ENCRYPTION AS
'+REPLICATE('-', 40003 - @procNameLength)
else if @objtype='FN'
SET @fake_01='ALTER FUNCTION '+ @procedure +'() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
/*'+REPLICATE('*', datalength(@real_01) /2 - @procNameLength)+'*/ END'
else if @objtype='V'
SET @fake_01='ALTER view '+ @procedure +' WITH ENCRYPTION AS select 1 as col
/*'+REPLICATE('*', datalength(@real_01) /2 - @procNameLength)+'*/'
else if @objtype='TR'
SET @fake_01='ALTER trigger '+ @procedure +' ON '+@parentname+'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
/*'+REPLICATE('*', datalength(@real_01) /2 - @procNameLength)+'*/'
EXECUTE (@fake_01)
--從sys.sysobjvalues里提出加密的假的
SET @fake_encrypt_01=(SELECT top 1 imageval FROM sys.sysobjvalues WHERE objid =
object_id(@procedure) and valclass = 1 order by subobjid )
if @objtype='P'
SET @fake_01='Create PROCEDURE '+ @procedure +' WITH ENCRYPTION AS
'+REPLICATE('-', 40003 - @procNameLength)
else if @objtype='FN'
SET @fake_01='CREATE FUNCTION '+ @procedure +'() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
/*'+REPLICATE('*', datalength(@real_01) /2 - @procNameLength)+'*/ END'
else if @objtype='V'
SET @fake_01='Create view '+ @procedure +' WITH ENCRYPTION AS select 1 as col
/*'+REPLICATE('*', datalength(@real_01) /2 - @procNameLength)+'*/'
else if @objtype='TR'
SET @fake_01='Create trigger '+ @procedure +' ON '+@parentname+'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
/*'+REPLICATE('*', datalength(@real_01) /2 - @procNameLength)+'*/'
--開始計數
SET @intProcSpace=1
--使用字符填充臨時變量
SET @real_decrypt_01 = replicate(N'A', (datalength(@real_01) /2 ))
--循環設置每一個變量，創建真正的變量
--每次一個字節
SET @intProcSpace=1
--如有必要，遍歷每個@real_xx變量并解密
WHILE @intProcSpace<=(datalength(@real_01)/2)
BEGIN
--真的和假的和加密的假的進行異或處理
SET @real_decrypt_01 = stuff(@real_decrypt_01, @intProcSpace, 1,
NCHAR(UNICODE(substring(@real_01, @intProcSpace, 1)) ^
(UNICODE(substring(@fake_01, @intProcSpace, 1)) ^
UNICODE(substring(@fake_encrypt_01, @intProcSpace, 1)))))
SET @intProcSpace=@intProcSpace+1
END
--通過sp_helptext邏輯向表#output里插入變量
insert #output (real_decrypt) select @real_decrypt_01
-- select real_decrypt AS '#output chek' from #output --測試
-- -------------------------------------
--開始從sp_helptext提取
-- -------------------------------------
declare @dbname sysname
,@BlankSpaceAdded int
,@BasePos int
,@CurrentPos int
,@TextLength int
,@LineId int
,@AddOnLen int
,@LFCR int --回車換行的長度
,@DefinedLength int
,@SyscomText nvarchar(4000)
,@Line nvarchar(255)
Select @DefinedLength = 255
SELECT @BlankSpaceAdded = 0 --跟蹤行結束的空格。注意Len函數忽略了多余的空格
CREATE TABLE #CommentText
(LineId int
,Text nvarchar(255) collate database_default)
--使用#output代替sys.sysobjvalues
DECLARE ms_crs_syscom CURSOR LOCAL
FOR SELECT real_decrypt from #output
ORDER BY ident
FOR READ ONLY
--獲取文本
SELECT @LFCR = 2
SELECT @LineId = 1
OPEN ms_crs_syscom
FETCH NEXT FROM ms_crs_syscom into @SyscomText
WHILE @@fetch_status >= 0
BEGIN
SELECT @BasePos = 1
SELECT @CurrentPos = 1
SELECT @TextLength = LEN(@SyscomText)
WHILE @CurrentPos != 0
BEGIN
--通過回車查找行的結束
SELECT @CurrentPos = CHARINDEX(char(13)+char(10), @SyscomText,
@BasePos)
--如果找到回車
IF @CurrentPos != 0
BEGIN
--如果@Lines的長度的新值比設置的大就插入@Lines目前的內容并繼續
While (isnull(LEN(@Line),0) + @BlankSpaceAdded +
@CurrentPos-@BasePos + @LFCR) > @DefinedLength
BEGIN
SELECT @AddOnLen = @DefinedLength-(isnull(LEN(@Line),0) +
@BlankSpaceAdded)
INSERT #CommentText VALUES
( @LineId,
isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText,
@BasePos, @AddOnLen), N''))
SELECT @Line = NULL, @LineId = @LineId + 1,
@BasePos = @BasePos + @AddOnLen, @BlankSpaceAdded = 0
END
SELECT @Line = isnull(@Line, N'') +
isnull(SUBSTRING(@SyscomText, @BasePos, @CurrentPos-@BasePos + @LFCR), N'')
SELECT @BasePos = @CurrentPos+2
INSERT #CommentText VALUES( @LineId, @Line )
SELECT @LineId = @LineId + 1
SELECT @Line = NULL
END
ELSE
--如果回車沒找到
BEGIN
IF @BasePos <= @TextLength
BEGIN
--如果@Lines長度的新值大于定義的長度
While (isnull(LEN(@Line),0) + @BlankSpaceAdded +
@TextLength-@BasePos+1 ) > @DefinedLength
BEGIN
SELECT @AddOnLen = @DefinedLength -
(isnull(LEN(@Line),0) + @BlankSpaceAdded)
INSERT #CommentText VALUES
( @LineId,
isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText,
@BasePos, @AddOnLen), N''))
SELECT @Line = NULL, @LineId = @LineId + 1,
@BasePos = @BasePos + @AddOnLen, @BlankSpaceAdded =
0
END
SELECT @Line = isnull(@Line, N'') +
isnull(SUBSTRING(@SyscomText, @BasePos, @TextLength-@BasePos+1 ), N'')
if LEN(@Line) < @DefinedLength and charindex(' ',
@SyscomText, @TextLength+1 ) > 0
BEGIN
SELECT @Line = @Line + ' ', @BlankSpaceAdded = 1
END
END
END
END
FETCH NEXT FROM ms_crs_syscom into @SyscomText
END
IF @Line is NOT NULL
INSERT #CommentText VALUES( @LineId, @Line )
select Text from #CommentText order by LineId
CLOSE ms_crs_syscom
DEALLOCATE ms_crs_syscom
DROP TABLE #CommentText
-- -------------------------------------
--結束從sp_helptext提取
-- -------------------------------------
--刪除用短橫線創建的存儲過程并重建原始的存儲過程
ROLLBACK TRAN
DROP TABLE #output
3、一般存儲過程格式
if exists (select 1
from sysobjects
where id = object_id('usp_xxxx')
and type = 'P')
drop proc usp_xxxx
go
CREATE PROCEDURE usp_xxxx
(
@param1 int
,@param2 varchar(200)=''
)
WITH ENCRYPTION
AS
/******************************************************************************
** Name: usp_xxxx
** Desc:
**
** Return Values:
** Author:
** Date:
*******************************************************************************/
DECLARE @vtmpStr varchar(200)
DECLARE @queryStr varchar(5000)=''
DECLARE @rowStr varchar(2000)=''
DECLARE @sqlStr varchar(2000)=''
---- 查詢條件 --------------------------------------------
IF @param1 >0 --供應商產品編號
SET @queryStr=' And AAAA = '+CAST(@param1 as varchar(20))+@queryStr
IF LEN(@param2) >0 --供應商名稱
SET @queryStr=' And ( BBBB LIKE '+CHAR(39)+'%'+@param2+'%'+CHAR(39) +' ) ' +@queryStr
----- 分頁 ------------------------
IF @rowStart IS NOT NULL AND @rowEnd IS NOT NULL --啟用分頁
SET @rowStr= ' WHERE IDRank BETWEEN '+CAST( @rowStart as Varchar(20) )
+ ' AND '+CAST( @rowEnd as Varchar(20) )
SET @sqlStr='
SELECT * FROM (
SELECT DISTINCT
AAAAA
,BBBB
,ROW_NUMBER() OVER(ORDER BY '+ @orderby +') as IDRank
FROM tb1 '
SET @sqlStr+=' WHERE 1=1 '
+ @queryStr
+ ' ) AS IDWithRowNumber '
Exec(@sqlStr+@rowStr+ ' ORDER BY IDRank ASC ') --查詢出結果集
--SELECT @sqlStr+@rowStr
SET @sqlStr = REPLACE(@sqlStr,'SELECT * FROM','SELECT COUNT(*) as count FROM') --統計記錄總數
Exec(@sqlStr)
--
If @@Error<>0
Begin
Select @vtmpStr ='查詢信息出錯！'
Goto err_handle
End
Return
err_handle:
Select @vtmpStr = '調用usp_xxxx：'+@vtmpStr+char(30)
RaisError (@vtmpStr,16,1)
posted on 2009-09-10 17:07
黃小二 閱讀(2641)
評論(3) 編輯 收藏 所屬分類:
[DB].SQL Server