林俊海的博客

makecab.exe 原來默認是限制文件大小的，故原來在壓縮的文件較大時會出現(xiàn)錯誤，現(xiàn)已更正了這個錯誤  回復(fù)  更多評論
  

可以用,支持  回復(fù)  更多評論
  

感謝博主!
我有一個cab文件,想替換包里面的一個同名文件,(被替換的文件和改文件大小相同)請問makecab文件從新制作cab后,發(fā)現(xiàn)大了很多,放到原來的安裝目錄下去再安裝軟件,提示錯誤.
請問如何解決?謝謝  回復(fù)  更多評論
  

用 Makecab.exe 打包 CAB 有兩種壓縮方式(默認模式、高壓縮率模式)。
原來的程序只使用默認的模式壓縮文件。
現(xiàn)在程序已更新，加入了使用高壓縮率模式的選項功能。
重新下載即可。

感謝 山東人 的信息，要不還真忘了加這個重要選項

至于更新 CAB 后安裝程序發(fā)生錯誤，具體是什么情況還不清楚，能否提供更詳細信息，也讓我學(xué)習學(xué)習。

  回復(fù)  更多評論
  

謝謝樓住，正在學(xué)網(wǎng)頁控件，需要，  回復(fù)  更多評論
  

不錯！
很棒！
  回復(fù)  更多評論
  

很好的東東哦，謝謝了！  回復(fù)  更多評論
  

謝謝了！ 不過我還有一個CAB打包工具，是老毛桃制作的，也是調(diào)用makecab.exe來打包的，不過使用的是命令行，現(xiàn)在也給你分享其源碼。如下： （注：將下列所有的字復(fù)制到記事本并保存為CMD即可。）

@Echo Off
Set TT=老毛桃制作的批量文件 CAB 打包工具
Set TS=如果你輸入的路徑或文件名中有空格，請在外邊用上引號
COLOR 2F
TITLE %TT%
Set ERR=
Set C0=MAKECAB /D CompressionType=LZX /D CompressionMemory=21 /D MaxDiskSize=CDROM /D Cabinet=On /D Compress=On /D FolderSizeThreshold=5000000

:BEGIN
CLS
Echo.
Echo 　　　　　　　╭══════════════════╮
Echo 　　　　　　　║　　　　　　　　　　　　　　　　　　║
Echo 　　　╭═══┤ %TT%! ├═══╮
Echo 　　　║　　　║　　　　　　　　　　　　　　　　　　║　　　║
Echo 　　　║　　　╰══════════════════╯　　　║
Echo 　　　║　　　　　　　　　　　　　　　　　　　　　　　　　　║
Echo 　　　║　　 您是需要將批量文件制作成一個壓縮包呢？　　　　 ║
Echo 　　　║　　 還是想生成 N 個 CAB 格式的單獨壓縮文件？　　　 ║
Echo 　　　║　　　　　　　　　　　　　　　　　　　　　　　　　　║
Echo 　　　║　　　 [1] 將批量文件制作成一個壓縮包　　　　　　　 ║
Echo 　　　║　　　 [2] 將每個文件制作成單獨壓縮文件　　　　　　 ║
Echo 　　　║　　　 [3] 將單個文件制作成單獨壓縮文件　　　　　　 ║
Echo 　　　║　　　 [Q] 退出　　　　　　　　　　　　　　　　　　 ║
Echo 　　　║　　　　　　　　　　　　　　　　　　　　　　　　　　║
Echo 　　　╟──────────────────────────╢
Echo 　　　║ 注：1. 待壓縮文件的父目錄需與本程序在同一路徑下；　║
Echo 　　　║　　 2. 待壓縮文件所在路徑(包括父路徑)不許有空格。　║
Echo 　　　╟══════════════════════════╢
Echo 　　　║　版權(quán)所有：老毛桃　　　　僅供網(wǎng)友們交流，翻版不究　║
Echo 　　　╰──────────────────────────╯
Echo.
Set Choice=
Set /P Choice=　　　　請選擇要進行的操作（1/2/3/Q），然后按回車：

If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' GOTO LOOPA
If /I '%Choice%'=='2' GOTO LOOPA
If /I '%Choice%'=='3' GOTO LOOPD
If /I '%Choice%'=='Q' EXIT
Goto BEGIN

:LOOPA
If /I '%Choice%'=='1' (
TITLE %TT% - 制作成一個壓縮包
)
If /I '%Choice%'=='2' (
TITLE %TT% - 制作成多個單獨壓縮文件
)
If "%Err%"=="" (
CLS
)
Echo 請輸入需壓縮的文件所在的目錄名，如 Files
Echo 注意：1.%TS%
Echo.
Set Ds=
Set /P Ds=請輸入：
If %Ds%A==A (
Set Err=
Goto LOOPA
)
If Not Exist %Ds% (
Set Err=1
Echo.
CLS
Echo 您所輸入的路徑不存在，請重新輸入
Echo.
Goto LOOPA
)

If /I '%Choice%'=='1' GOTO LOOPB
Goto LOOPC

:LOOPB
CLS
Echo 請輸入需要保存的壓縮包文件名，如 Drive.CAB
Echo 注意：1.%TS%
Echo.
Set FCab=
Set /P FCab=請輸入：
If %FCab%A==A Goto LOOPB
Set C=%C0% /D DiskDirectoryTemplate=.\ /D CabinetNameTemplate=%FCab%
Set TF=%TEMP%\Files.tmp
If Exist "%TF%" Del "%TF%" >NUL
For %%i In (%Ds%) Do Set FP=%%~dpi
SETLOCAL ENABLEDELAYEDEXPANSION
For /f "delims=" %%i In ('dir %Ds% /s /b /a-d') Do (
Set str=%%i
Set "str=!str:%FP%%Ds%\=!"
>>%TF% Echo "%%i" "!str!"
)
ENDLOCAL
%C% /F %TF%
Del /F /S /Q "%TF%" SETUP.INF SETUP.RPT >NUL
Goto Exit

:LOOPC
CLS
Echo 請輸入需要保存的 CAB 格式文件所在路徑，比如 OutFile
Echo 如果此路徑不存在，將在當前目錄下自動創(chuàng)建。
Echo 注意：1.%TS%
Echo.
Set OUT=
Set /P OUT=請輸入：
If %OUT%A==A Goto LOOPC

For %%i In (%Ds%) Do Set FP=%%~dpi
SETLOCAL ENABLEDELAYEDEXPANSION
For /f "delims=" %%i In ('dir %Ds% /s /b /a-d') Do (
Set str=%%~dpi
Set str=!str:%FP%%Ds%\=!
Set str=%OUT%\!str!
Set str=!str:~0,-1!
%C0% /L "!str!" "%%i"
)
ENDLOCAL
Goto Exit

:LOOPD
TITLE %TT% - 只壓縮一個文件
If "%Err%"=="" (
CLS
)
Echo 請輸入需要壓縮的文件所在路徑，比如 Driver\NV4_Disp.SYS
Echo 其中 Driver 與本程序在同一文件夾中
Echo 您也可以選擇按 TAB 鍵快速輸入路徑和文件名稱，完成后按回車確認
Echo.
Echo 注意：1.%TS%
Echo.
Set FileR=
Set /P FileR=請輸入：
If %FileR%A==A (
CLS
Goto LOOPD
)
If Not Exist %FileR% (
Set Err=1
Echo.
CLS
Echo 您所輸入的文件路徑不存在，請重新輸入
Echo.
Goto LOOPD
)
Goto LOOPE

:LOOPE
CLS
Echo 請輸入需要保存的壓縮文件路徑，比如 Driver\NV4_Disp.CAB
Echo 如果不輸入文件路徑，則以 NV4_Disp.SY_ 的形式保存在本程序所在路徑
Echo.
Echo 注意：1.如果嘗試輸入一個不存在的路徑信息，壓縮程序會出錯！
Echo 　　　2.%TS%
Echo.
Set FileT=
Set /P FileT=請輸入：
%C0% %FileR% %FileT%
Goto Exit

:Exit
Echo.
Echo.
Echo.
Echo 您需要的操作已經(jīng)全部完成，請核查. . .
Echo.
Echo 老毛桃感謝您的使用，如果您有什么好的建議，請 QQ 我！
Echo.
Echo.
Echo 請按任意鍵退出程序. . .
PAUSE >NUL  回復(fù)  更多評論
  

^_^

謝謝，我收下了  回復(fù)  更多評論
  

ok  回復(fù)  更多評論
  

多謝樓主！真的很好用！
  回復(fù)  更多評論
  

做成的CAB文件在手機安裝不了，提示錯誤  回復(fù)  更多評論