/*
普通行列轉(zhuǎn)換
(愛新覺羅.毓華 2007-11-18于海南三亞)

假設(shè)有張學(xué)生成績表(tb)如下:
Name Subject Result
張三 語文　　74
張三 數(shù)學(xué)　　83
張三 物理　　93
李四 語文　　74
李四 數(shù)學(xué)　　84
李四 物理　　94
*/

-------------------------------------------------------------------------
/*
想變成
姓名 語文 數(shù)學(xué) 物理
---------- ----------- ----------- -----------
李四 74 84 94
張三 74 83 93
*/

create table tb
(
Name    varchar(10) ,
Subject varchar(10) ,
Result  int
)
insert into tb(Name , Subject , Result) values('張三' , '語文' , 74)
insert into tb(Name , Subject , Result) values('張三' , '數(shù)學(xué)' , 83)
insert into tb(Name , Subject , Result) values('張三' , '物理' , 93)
insert into tb(Name , Subject , Result) values('李四' , '語文' , 74)
insert into tb(Name , Subject , Result) values('李四' , '數(shù)學(xué)' , 84)
insert into tb(Name , Subject , Result) values('李四' , '物理' , 94)
go
--靜態(tài)SQL,指subject只有語文、數(shù)學(xué)、物理這三門課程。
select name 姓名,
max(case subject when '語文' then result else 0 end) 語文,
max(case subject when '數(shù)學(xué)' then result else 0 end) 數(shù)學(xué),
max(case subject when '物理' then result else 0 end) 物理
from tb
group by name

/*
姓名 語文 數(shù)學(xué) 物理
---------- ----------- ----------- -----------
李四 74 84 94
張三 74 83 93
*/

--動態(tài)SQL,指subject不止語文、數(shù)學(xué)、物理這三門課程。
declare @sql varchar(8000)
set @sql = 'select Name as ' + '姓名'
select @sql = @sql + ' , max(case Subject when ''' + Subject + ''' then Result else 0 end) [' + Subject + ']'
from (select distinct Subject from tb) as a
set @sql = @sql + ' from tb group by name'
exec(@sql) 

/*
姓名 數(shù)學(xué) 物理 語文
---------- ----------- ----------- -----------
李四 84 94 74
張三 83 93 74
*/

-------------------------------------------------------------------
/*加個平均分，總分
姓名 語文 數(shù)學(xué) 物理 平均分 總分
---------- ----------- ----------- ----------- -------------------- -----------
李四 74 84 94 84.00 252
張三 74 83 93 83.33 250
*/

--靜態(tài)SQL,指subject只有語文、數(shù)學(xué)、物理這三門課程。
select name 姓名,
max(case subject when '語文' then result else 0 end) 語文,
max(case subject when '數(shù)學(xué)' then result else 0 end) 數(shù)學(xué),
max(case subject when '物理' then result else 0 end) 物理,
cast(avg(result*1.0) as decimal(18,2)) 平均分,
sum(result) 總分
from tb
group by name

/*
姓名 語文 數(shù)學(xué) 物理 平均分 總分
---------- ----------- ----------- ----------- -------------------- -----------
李四 74 84 94 84.00 252
張三 74 83 93 83.33 250
*/

--動態(tài)SQL,指subject不止語文、數(shù)學(xué)、物理這三門課程。
declare @sql1 varchar(8000)
set @sql1 = 'select Name as ' + '姓名'
select @sql1 = @sql1 + ' , max(case Subject when ''' + Subject + ''' then Result else 0 end) [' + Subject + ']'
from (select distinct Subject from tb) as a
set @sql1 = @sql1 + ' , cast(avg(result*1.0) as decimal(18,2)) 平均分,sum(result) 總分 from tb group by name'
exec(@sql1) 

/*
姓名 數(shù)學(xué) 物理 語文 平均分 總分
---------- ----------- ----------- ----------- -------------------- -----------
李四 84 94 74 84.00 252
張三 83 93 74 83.33 250
*/